mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
57 lines
1.4 KiB
Plaintext
57 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Draws the current temp marker. Allows rotation.
|
|
*
|
|
* Arguments:
|
|
* 0: TheMap <Control>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [theMapControl] call ace_markers_fnc_mapDrawEH;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_theMap"];
|
|
// TRACE_1("params",_theMap);
|
|
|
|
//Only show if marker place is open:
|
|
if (isNull findDisplay 54) exitWith {};
|
|
//Error checking:
|
|
if (GVAR(currentMarkerConfigName) == "" || {GVAR(currentMarkerColorConfigName) == ""} || {GVAR(currentMarkerPosition) isEqualTo []}) exitWith {
|
|
ERROR("Bad Data");
|
|
};
|
|
|
|
private _sizeX = 1;
|
|
private _sizeY = 1;
|
|
|
|
private _textureConfig = configFile >> "CfgMarkers" >> GVAR(currentMarkerConfigName);
|
|
private _texture = getText (_textureConfig >> "icon");
|
|
private _markerSize = getNumber (_textureConfig >> "size");
|
|
private _markerShadow = getNumber (_textureConfig >> "shadow");
|
|
private _colorConfig = (configFile >> "CfgMarkerColors" >> GVAR(currentMarkerColorConfigName));
|
|
private _drawColor = getArray (_colorConfig >> "color");
|
|
|
|
//Convert possible code into numbers
|
|
{
|
|
if (_x isEqualType "") then {
|
|
_drawColor set [_forEachIndex, call compile _x];
|
|
};
|
|
} forEach _drawColor;
|
|
|
|
_drawColor set [3, (_drawColor select 3) * 0.875]; //Arma adds a slight transparency
|
|
|
|
_theMap drawIcon [
|
|
_texture,
|
|
_drawColor,
|
|
GVAR(currentMarkerPosition),
|
|
_sizeX * _markerSize,
|
|
_sizeY * _markerSize,
|
|
GVAR(currentMarkerAngle),
|
|
"",
|
|
_markerShadow
|
|
];
|