mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
67 lines
1.7 KiB
Plaintext
67 lines
1.7 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Garth 'L-H' de Wet
|
|
* Handles rain effects being created on glasses.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* call ace_goggles_fnc_applyRainEffect;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
private _unit = ACE_player;
|
|
|
|
if (!alive _unit) exitWith {};
|
|
|
|
private _fnc_underCover = {
|
|
params ["_unit"];
|
|
|
|
if (vehicle _unit != _unit && {!isTurnedOut _unit}) exitWith {true};
|
|
|
|
// looking up and no roof over head
|
|
private _position = eyePos _unit;
|
|
positionCameraToWorld [0, 0, 1] select 2 < (positionCameraToWorld [0, 0, 0] select 2) - 0.4 || {(lineIntersects [_position, _position vectorAdd [0, 0, 15], _unit])} // return
|
|
};
|
|
|
|
if (!isNull findDisplay 312) exitWith {
|
|
if (GVAR(RainActive)) then {
|
|
call FUNC(removeRainEffect);
|
|
};
|
|
};
|
|
|
|
// Ignore if unit is under water
|
|
if !(GVAR(EffectsActive) || {underwater _unit}) exitWith {
|
|
call FUNC(RemoveRainEffect);
|
|
};
|
|
|
|
if (GVAR(RainLastLevel) != rain) then {
|
|
call FUNC(RemoveRainEffect);
|
|
|
|
GVAR(RainLastLevel) = rain;
|
|
|
|
// Rain is happening
|
|
if (GVAR(RainLastLevel) > 0.05 && {!([_unit] call _fnc_underCover)}) then {
|
|
GVAR(RainActive) = true;
|
|
GVAR(RainDrops) = "#particlesource" createVehicleLocal position _unit;
|
|
GVAR(RainDrops) setParticleClass "ACERainEffect";
|
|
GVAR(RainDrops) setDropInterval (0.07 * (1.1 - GVAR(RainLastLevel)));
|
|
GVAR(RainDrops) attachTo [vehicle _unit, [0,0,0]];
|
|
};
|
|
} else {
|
|
if (GVAR(RainLastLevel) > 0.05) then {
|
|
if (GVAR(RainActive) && {[_unit] call _fnc_underCover}) exitWith {
|
|
call FUNC(RemoveRainEffect);
|
|
};
|
|
|
|
if !(GVAR(RainActive)) then {
|
|
GVAR(RainLastLevel) = -1;
|
|
};
|
|
};
|
|
};
|