mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
42 lines
1.4 KiB
Plaintext
42 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Adds a key to a unit that will open a vehicle
|
|
* Note: has global effects for Unit (will add items to remote unit)
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Vehicle <OBJECT>
|
|
* 2: custom key (true: custom key (magazine) - false: side key (item)) <BOOL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [ACE_player, car, true] call ACE_VehicleLock_fnc_addKeyForVehicle
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
if (!params [["_unit", objNull, [objNull]], ["_veh", objNull, [objNull]], ["_useCustom", false, [false]]]) exitWith {
|
|
ERROR("Input wrong type");
|
|
};
|
|
TRACE_3("params",_unit,_veh,_useCustom);
|
|
|
|
if (isNull _unit) exitWith {ERROR("null unit");};
|
|
if (isNull _veh) exitWith {ERROR("null vehicle");};
|
|
|
|
if (_useCustom) then {
|
|
private _previousMags = magazinesDetail _unit;
|
|
_unit addMagazine ["ACE_key_customKeyMagazine", 1]; //addMagazine array has global effects
|
|
private _newMags = (magazinesDetail _unit) - _previousMags;
|
|
if ((count _newMags) == 0) exitWith {ERROR("failed to add magazine (inventory full?)");};
|
|
private _keyMagazine = _newMags select 0;
|
|
TRACE_2("setting up key on server",_veh,_keyMagazine);
|
|
//Have the server run add the key to the vehicle's key array:
|
|
[QGVAR(setupCustomKey), [_veh, _keyMagazine]] call CBA_fnc_serverEvent;
|
|
} else {
|
|
private _keyName = [_veh] call FUNC(getVehicleSideKey);
|
|
_unit addItem _keyName; //addItem has global effects
|
|
};
|