mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
63 lines
1.7 KiB
Plaintext
63 lines
1.7 KiB
Plaintext
#include "script_component.hpp"
|
|
#include "..\defines.hpp"
|
|
/*
|
|
* Author: Alganthe
|
|
* Clear the current container.
|
|
*
|
|
* Arguments:
|
|
* 0: Arsenal display <DISPLAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_display"];
|
|
|
|
// Clear container
|
|
switch (GVAR(currentLeftPanel)) do {
|
|
case IDC_buttonUniform: {
|
|
{GVAR(center) removeItemFromUniform _x} foreach (uniformItems GVAR(center));
|
|
GVAR(currentItems) set [15, []];
|
|
};
|
|
case IDC_buttonVest: {
|
|
{GVAR(center) removeItemFromVest _x} foreach (vestItems GVAR(center));
|
|
GVAR(currentItems) set [16, []];
|
|
};
|
|
case IDC_buttonBackpack: {
|
|
{GVAR(center) removeItemFromBackpack _x} foreach (backpackItems GVAR(center));
|
|
GVAR(currentItems) set [17, []];
|
|
};
|
|
};
|
|
|
|
// Clear number of owned items
|
|
private _ctrlList = _display displayCtrl IDC_rightTabContentListnBox;
|
|
|
|
for "_l" from 0 to (lbSize _ctrlList - 1) do {
|
|
_ctrlList lnbSetText [[_l, 2], str 0];
|
|
};
|
|
|
|
private _removeAllCtrl = _display displayCtrl IDC_buttonRemoveAll;
|
|
_removeAllCtrl ctrlSetFade 1;
|
|
_removeAllCtrl ctrlCommit FADE_DELAY;
|
|
|
|
// Update load bar
|
|
private _loadIndicatorBarCtrl = _display displayCtrl IDC_loadIndicatorBar;
|
|
_loadIndicatorBarCtrl progressSetPosition 0;
|
|
|
|
private _maxLoad = switch (GVAR(currentLeftPanel)) do {
|
|
case IDC_buttonUniform: {
|
|
gettext (configfile >> "CfgWeapons" >> uniform GVAR(center) >> "ItemInfo" >> "containerClass")
|
|
};
|
|
case IDC_buttonVest: {
|
|
gettext (configfile >> "CfgWeapons" >> vest GVAR(center) >> "ItemInfo" >> "containerClass")
|
|
};
|
|
case IDC_buttonBackpack: {
|
|
backpack GVAR(center)
|
|
};
|
|
};
|
|
|
|
private _control = _display displayCtrl IDC_rightTabContentListnBox;
|
|
[_control, _maxLoad] call FUNC(updateRightPanel);
|