mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
44 lines
1.4 KiB
Plaintext
44 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Alganthe
|
|
* Text statement for the weapon muzzle velocity stat
|
|
*
|
|
* Arguments:
|
|
* 0: Not used
|
|
* 1: item config path (CONFIG)
|
|
*
|
|
* Return Value:
|
|
* String to display
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["", "_config"];
|
|
|
|
if (EGVAR(arsenal,currentLeftPanel) == 2002) then {
|
|
private _primaryMag = primaryWeaponMagazine EGVAR(arsenal,center);
|
|
|
|
[primaryWeapon EGVAR(arsenal,center), _primaryMag param [0, ""]]
|
|
} else {
|
|
private _primaryMag = handgunMagazine EGVAR(arsenal,center);
|
|
|
|
[handgunWeapon EGVAR(arsenal,center), _primaryMag param [0, ""]]
|
|
} params ["_weapon", "_magazine"];
|
|
|
|
if (_magazine isEqualTo "") then {
|
|
localize "str_empty";
|
|
} else {
|
|
private _ammoCfg = (configFile >> "CfgAmmo" >> (getText (configFile >> "CfgMagazines" >> _magazine >> "ammo")));
|
|
private _barrelLength = getNumber (_config >> "ACE_barrelLength");
|
|
private _muzzleVelocityTable = getArray (_ammoCfg >> "ACE_muzzleVelocities");
|
|
private _barrelLengthTable = getArray (_ammoCfg >> "ACE_barrelLengths");
|
|
|
|
if (_barrelLength != 0 && {count _muzzleVelocityTable > 0} && {count _barrelLengthTable > 0}) then {
|
|
private _muzzleVelocity = [_barrelLength, _muzzleVelocityTable, _barrelLengthTable, 0] call EFUNC(advanced_ballistics,calculateBarrelLengthVelocityShift);
|
|
|
|
format ["%1 m/s (%2 ft/s)", _muzzleVelocity toFixed 0, (_muzzleVelocity * 3.28084) toFixed 0]
|
|
} else {
|
|
localize "str_empty";
|
|
};
|
|
};
|