mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
76 lines
2.6 KiB
Plaintext
76 lines
2.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: esteldunedain
|
|
* Insert an ACE action to a class, under a certain path
|
|
* Note: This function is NOT global.
|
|
*
|
|
* Arguments:
|
|
* 0: TypeOf of the class <STRING>
|
|
* 1: Type of action, 0 for actions, 1 for self-actions <NUMBER>
|
|
* 2: Parent path of the new action <ARRAY>
|
|
* 3: Action <ARRAY>
|
|
* 4: Use Inheritance <BOOL> (default: false)
|
|
*
|
|
* Return Value:
|
|
* The entry full path, which can be used to remove the entry, or add children entries <ARRAY>.
|
|
*
|
|
* Example:
|
|
* [typeOf cursorTarget, 0, ["ACE_TapShoulderRight"],VulcanPinchAction] call ace_interact_menu_fnc_addActionToClass;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
if (!params [["_objectType", "", [""]], ["_typeNum", 0, [0]], ["_parentPath", [], [[]]], ["_action", [], [[]], 11]]) exitWith {
|
|
ERROR("Bad Params");
|
|
[]
|
|
};
|
|
TRACE_4("params",_objectType,_typeNum,_parentPath,_action);
|
|
|
|
if (param [4, false, [false]]) exitwith {
|
|
if (isNil QGVAR(inheritedActions)) then {GVAR(inheritedActions) = [];};
|
|
private _index = GVAR(inheritedActions) pushBack [[], _typeNum, _parentPath, _action];
|
|
private _initEH = compile format ['
|
|
params ["_object"];
|
|
private _typeOf = typeOf _object;
|
|
(GVAR(inheritedActions) select %1) params ["_addedClasses", "_typeNum", "_parentPath", "_action"];
|
|
if (_typeOf in _addedClasses) exitWith {};
|
|
_addedClasses pushBack _typeOf;
|
|
[_typeOf, _typeNum, _parentPath, _action] call FUNC(addActionToClass);
|
|
', _index];
|
|
TRACE_2("Added inheritable action",_objectType,_index);
|
|
[_objectType, "init", _initEH, true, [], true] call CBA_fnc_addClassEventHandler;
|
|
|
|
// Return the full path
|
|
(_parentPath + [_action select 0])
|
|
};
|
|
|
|
// Ensure the config menu was compiled first
|
|
if (_typeNum == 0) then {
|
|
[_objectType] call FUNC(compileMenu);
|
|
} else {
|
|
[_objectType] call FUNC(compileMenuSelfAction);
|
|
};
|
|
|
|
private _namespace = [GVAR(ActNamespace), GVAR(ActSelfNamespace)] select _typeNum;
|
|
private _actionTrees = _namespace getVariable _objectType;
|
|
if (isNil "_actionTrees") then {
|
|
_actionTrees = [];
|
|
_namespace setVariable [_objectType, _actionTrees];
|
|
};
|
|
|
|
if (_parentPath isEqualTo ["ACE_MainActions"]) then {
|
|
[_objectType, _typeNum] call FUNC(addMainAction);
|
|
};
|
|
|
|
private _parentNode = [_actionTrees, _parentPath] call FUNC(findActionNode);
|
|
if (isNil {_parentNode}) exitWith {
|
|
ERROR_4("Failed to add action - action (%1) to parent %2 on object %3 [%4]",(_action select 0),_parentPath,_objectType,_typeNum);
|
|
[]
|
|
};
|
|
|
|
// Add action node as children of the correct node of action tree
|
|
(_parentNode select 1) pushBack [_action,[]];
|
|
|
|
// Return the full path
|
|
(_parentPath + [_action select 0])
|