mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
47 lines
1.3 KiB
Plaintext
47 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: GitHawk
|
|
* Takes a magazine from an ammo truck.
|
|
*
|
|
* Arguments:
|
|
* 0: Params <ARRAY>
|
|
* 0: Unit <OBJECT>
|
|
* 1: Magazine Classname <STRING>
|
|
* 2: Ammo Truck <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [[player, "500Rnd_127x99_mag_Tracer_Red"]] call ace_rearm_fnc_takeSuccess
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_args"];
|
|
_args params ["_unit", "_magazineClass", "_truck"];
|
|
TRACE_3("takeSuccess",_unit,_magazineClass,_truck);
|
|
|
|
private _success = true;
|
|
if (GVAR(supply) > 0) then {
|
|
_success = [_truck, _magazineClass] call FUNC(removeMagazineFromSupply);
|
|
};
|
|
if !(_success) exitWith {WARNING_2("takeSuccess failed to take [%1] from [%2]",_magazineClass,_truck);};
|
|
|
|
[_unit, "forceWalk", "ACE_rearm", true] call EFUNC(common,statusEffect_set);
|
|
[_unit, "blockThrow", "ACE_rearm", true] call EFUNC(common,statusEffect_set);
|
|
private _dummy = [_unit, _magazineClass] call FUNC(createDummy);
|
|
[_dummy, _unit] call FUNC(pickUpAmmo);
|
|
|
|
private _actionID = _unit addAction [
|
|
format ["<t color='#FF0000'>%1</t>", localize ELSTRING(dragging,Drop)],
|
|
'(_this select 0) call FUNC(dropAmmo)',
|
|
nil,
|
|
20,
|
|
false,
|
|
true,
|
|
"",
|
|
'!isNull (_target getVariable [QGVAR(dummy), objNull])'
|
|
];
|
|
_unit setVariable [QGVAR(ReleaseActionID), _actionID];
|