mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
0644ad9ca2
* Added workaround functions for turret magazine ammo. * Switched to retrieving turrets dynamically instead of looking them up from an array. * Refactoring only, no functional changes * Repurposed getNeedRearmMagazines as a general purpose rearm info function + more. * The function retrieves all non-full magazines. This code was previously repeated in many different functions, but is now centralized in one. * Empty pylon filling is no longer supported in favor of the upcoming "pylons" ACE-module. Fixed bugs: * Rearm was using broken commands "magazineTurretAmmo" and "setMagazineTurretAmmo". They are now replaced with their corresponding workaround functions. * Pylon rearm was trying to set ammo count on empty pylons. Note: rearmSuccessLocal is not yet fixed! * Rearming no longer switches shell types in cannons/mortars. * Added Tuupertunut to authors. * Rearming no longer switches shell types. 2nd try. Last time it was fixed only if the turret is manned. Now it is fixed even when unmanned. * Updated fnc_rearm to support the earlier repurposing of fnc_getNeedRearmMagazines. * Small fixes and comments. * Renamed fnc_getVehicleMagazines to fnc_getTurretConfigMagazines. The latter describes much better what the function actually does. * Removed redundant checks. * Refactoring. * Fixed spaces in macros. * Renamed fnc_getAllTurrets to fnc_getAllRearmTurrets
43 lines
1.2 KiB
Plaintext
43 lines
1.2 KiB
Plaintext
/*
|
|
* Author: GitHawk
|
|
* Rearms a vehicle, after progress bar finishes, pass args to machine where turret is local.
|
|
*
|
|
* Arguments:
|
|
* 0: Vehicle <OBJECT>
|
|
* 1: Unit <OBJECT>
|
|
* 2: Turret Path <ARRAY>
|
|
* 3: Number of magazines <NUMBER>
|
|
* 4: Magazine Classname <STRING>
|
|
* 5: Number of rounds <NUMBER>
|
|
* 6: Pylon Index <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [vehicle, player, [-1], 2, "5000Rnd_762x51_Belt", 500, -1] call ace_rearm_fnc_rearmSuccess
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_vehicle", "_unit", "_turretPath", "_numMagazines", "_magazineClass", "_numRounds", "_pylon"];
|
|
TRACE_7("rearmSuccess",_vehicle,_unit,_turretPath,_numMagazines,_magazineClass,_numRounds,_pylon);
|
|
|
|
if (local _unit) then {
|
|
[_unit, true, true] call FUNC(dropAmmo);
|
|
};
|
|
|
|
if (!alive _vehicle) exitWith {WARNING("vehicle dead/null");};
|
|
|
|
if (isServer) then {
|
|
private _turretOwnerID = _vehicle turretOwner _turretPath;
|
|
if (_turretOwnerID == 0) then {
|
|
[QGVAR(rearmSuccessLocalEH), _this, [_vehicle]] call CBA_fnc_targetEvent;
|
|
} else {
|
|
[QGVAR(rearmSuccessLocalEH), _this, _turretOwnerID] call CBA_fnc_ownerEvent;
|
|
};
|
|
} else {
|
|
[QGVAR(rearmSuccessEH), _this] call CBA_fnc_serverEvent;
|
|
};
|