mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
52 lines
1.5 KiB
Plaintext
52 lines
1.5 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Read laser distance measurement from engine.
|
|
*
|
|
* Arguments:
|
|
* 0: Measurement Accuracy (default: 1) <NUMBER>
|
|
* 1: Maximum measure distance (default: 5000) <NUMBER>
|
|
* 2: Minimum measure distance (default: 0) <NUMBER>
|
|
* 3: Blank display on range error (default: false) <BOOL>
|
|
*
|
|
* Return Value:
|
|
* Measured distance <NUMBER>
|
|
*
|
|
* Example:
|
|
* [5, 6, 7, true] call ace_fcs_fnc_getRange
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params [["_accuracy",1], ["_maxDistance",5000], ["_minDistance",0], ["_blank",false]];
|
|
|
|
disableSerialization;
|
|
private _dlgRangefinder = uiNamespace getVariable ["ACE_dlgRangefinder", displayNull];
|
|
|
|
private _distance = parseNumber ctrlText (_dlgRangefinder displayCtrl 151);
|
|
|
|
if (_distance == 0) then {
|
|
_distance = _this call EFUNC(common,getTargetDistance);
|
|
} else {
|
|
// Is distance out of bound?
|
|
_distance = _distance min _maxDistance;
|
|
_distance = _distance max _minDistance;
|
|
|
|
// If don't let accuracy be less than 1
|
|
_accuracy = _accuracy max 1;
|
|
_distance = (round (_distance/_accuracy)) * _accuracy;
|
|
};
|
|
|
|
// Change the display if the range is out of bounds
|
|
if (_distance >= _maxDistance || _distance <= _minDistance) then {
|
|
if (_blank) then {
|
|
(_dlgRangefinder displayCtrl 1713151) ctrlSetText "----";
|
|
} else {
|
|
(_dlgRangefinder displayCtrl 1713151) ctrlSetText ([_distance, 4, 0] call CBA_fnc_formatNumber) + "*";
|
|
};
|
|
} else {
|
|
(_dlgRangefinder displayCtrl 1713151) ctrlSetText ([_distance, 4, 0] call CBA_fnc_formatNumber);
|
|
};
|
|
|
|
_distance
|