mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
54 lines
1.3 KiB
Plaintext
54 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: BaerMitUmlaut
|
|
* Handles ropes breaking when deployed.
|
|
*
|
|
* Arguments:
|
|
* 0: RopeBreak EH arguments <ARRAY>
|
|
* 1: Part of rope ("top" or "bottom") <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [[array]], "top"] call ace_fastroping_fnc_onRopeBreak
|
|
*
|
|
* Public: No
|
|
*/
|
|
params ["_ehArgs", "_part"];
|
|
_ehArgs params ["_rope", "_helper1", "_helper2"];
|
|
|
|
if (_part == "bottom") then {
|
|
_helper2 = (ropeAttachedObjects _helper1) select 0;
|
|
};
|
|
|
|
private _vehicle = attachedTo _helper2;
|
|
if (isNil "_vehicle") exitWith {}; //Exit when vehicle got destroyed
|
|
if (_vehicle isKindOf "ACE_friesBase") then {
|
|
_vehicle = attachedTo _vehicle;
|
|
};
|
|
|
|
private _deployedRopes = _vehicle getVariable [QGVAR(deployedRopes), []];
|
|
private _brokenRope = [];
|
|
{
|
|
if ((_x select 1 == _rope) || {(_x select 2 == _rope)}) exitWith {
|
|
_brokenRope = _x;
|
|
};
|
|
} forEach _deployedRopes;
|
|
_brokenRope set [6, true];
|
|
_vehicle setVariable [QGVAR(deployedRopes), _deployedRopes, true];
|
|
|
|
private _unit = {
|
|
if (_x isKindOf "CAManBase") exitWith {_x};
|
|
} forEach (attachedObjects (_brokenRope select 3));
|
|
|
|
if !(isNil "_unit") then {
|
|
if (_part == "top") then {
|
|
detach _unit;
|
|
} else {
|
|
//TODO: ???
|
|
//Rope might break at the very bottom
|
|
//-> letting the unit fall is not always ideal
|
|
};
|
|
};
|