mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
70 lines
2.0 KiB
Plaintext
70 lines
2.0 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: esteldunedain
|
|
* Creates an isolated ACE action
|
|
* Note: This function is NOT global.
|
|
*
|
|
* Arguments:
|
|
* 0: Action name <STRING>
|
|
* 1: Name of the action shown in the menu <STRING>
|
|
* 2: Icon file path or Array of icon file path and hex color ("" for default icon) <STRING|ARRAY>
|
|
* 3: Statement <CODE>
|
|
* 4: Condition <CODE>
|
|
* 5: Insert children code <CODE> (Optional)
|
|
* 6: Action parameters <ANY> (Optional)
|
|
* 7: Position (Position array, Position code or Selection Name) <ARRAY>, <CODE> or <STRING> (Optional)
|
|
* 8: Distance <NUMBER> (Optional)
|
|
* 9: Other parameters [showDisabled,enableInside,canCollapse,runOnHover,doNotCheckLOS] <ARRAY> (Optional)
|
|
* 10: Modifier function <CODE> (Optional)
|
|
*
|
|
* Return Value:
|
|
* Action <ARRAY>
|
|
*
|
|
* Example:
|
|
* ["VulcanPinch","Vulcan Pinch","",{_target setDamage 1;},{true},{},[parameters], [0,0,0], 100] call ace_interact_menu_fnc_createAction;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
// IGNORE_PRIVATE_WARNING(_actionName,_displayName,_icon,_statement,_condition,_insertChildren,_customParams,_position,_distance,_params,_modifierFunction);
|
|
|
|
params [
|
|
"_actionName",
|
|
"_displayName",
|
|
"_icon",
|
|
"_statement",
|
|
"_condition",
|
|
["_insertChildren", {}],
|
|
["_customParams", []],
|
|
["_position", {[0, 0, 0]}],
|
|
["_distance", 2],
|
|
["_params", [false, false, false, false, false]],
|
|
["_modifierFunction", {}]
|
|
];
|
|
|
|
_position = if (_position isEqualType "") then {
|
|
// If the action is set to a selection, create the suitable code - IGNORE_PRIVATE_WARNING(_target);
|
|
compile format ["_target selectionPosition '%1'", _position];
|
|
} else {
|
|
if (_position isEqualType []) then {
|
|
// If the action is set to a array position, create the suitable code
|
|
compile format ["%1", _position];
|
|
} else {
|
|
_position;
|
|
};
|
|
};
|
|
|
|
[
|
|
_actionName,
|
|
_displayName,
|
|
_icon,
|
|
_statement,
|
|
_condition,
|
|
_insertChildren,
|
|
_customParams,
|
|
_position,
|
|
_distance,
|
|
_params,
|
|
_modifierFunction
|
|
]
|