mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
abe2ce2f6f
* abc * Revert "abc" This reverts commitbcb4214bd9. * Update to current commit * Ports over NouberNou's dragon guidance * Add Dragon model * Make the Dragon CSW capable * Fix bugs regarding argument order * Add Dragon Attack Profile. Change how missileGuidance guidance_pfh works in order to allow for different types of missiles besides continious thrust * Fix bug regarding missile direction. Add official US Army training manual for the dragon for reference purposes * Adjust model to reflect real-life one * Add attackProfile and guidanceProfile onFired functions * Change Dragon "onFired" to reflect missileGuidance changes * Only implementing the Super-Dragon. Remove Tabs. Add new lines to all files. Add string-table. Tweak missile flight dynamics * Add sight description * Fix inheritance issues. Missile damage values tweaked. Fix String Table. Add backblast area. * Add feature wiki page. * Fix picture issues * Remove Dragon manual * add missing semi-colon * Tweak damage values. Fix formatting. Add lazy evaluation where applicable * Disable the ability to switch to the unusable launcher. Convert rvmat numbers to equivalent but more readable numbers. Multiple code fixes. ace_csw required. Formatting fixes. TGA -> PAA. Remove unused comments in missile guidance code * Dragon flight dynamics tweaked. Now assuming there is a booster angle creating wobble. Add a slight delay when the wire breaks to fire all of the service charges * hpp newline fixes. Case sensitivity for model and rvmat references * Update Wiki dependencies * Revert "Update Wiki dependencies" This reverts commitefc298c481. * fix dependency component * Changed inheritance structure to be more rigid. Remove un-needed config values. Fix script issues regarding positioning and the launchers aliveness * get rid of the optic for the base dragon. fucking bi configs not making sense * Lock non-useable dragon on initialization * Add model.cfg for animations * Fix formatting. Fix M47 Dragon Optic zoom * Change LOD selection names * Revert indentation, keep parenthesis. "Start, stop, start stop! Jesus! I'm starting to think Mattis is just a big cock tease" * Re-update indentation of model.cfg * Path fix. Whitespace fix * Sight attach/detach on same vehicle * If the sight gets detached, make sure the dragon goes dumb. Remove resetting of resting position when gunner gets out - looks stupid, but when the dragon is fired weird stuff happens * disable debug * Add EOF * Maybe finally fix EOF problem
61 lines
2.3 KiB
Plaintext
61 lines
2.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Brandon (TCVM)
|
|
* Attack profile: Wire guided
|
|
*
|
|
* Arguments:
|
|
* 0: Seeker Target PosASL <ARRAY>
|
|
* 1: Guidance Arg Array <ARRAY>
|
|
* 2: Attack Profile State <ARRAY>
|
|
*
|
|
* Return Value:
|
|
* Missile Aim PosASL <ARRAY>
|
|
*
|
|
* Example:
|
|
* [[1,2,3], [], []] call ace_hot_fnc_attackProfile_WIRE;
|
|
*
|
|
* Public: No
|
|
*/
|
|
params ["_seekerTargetPos", "_args", "_attackProfileStateParams"];
|
|
_args params ["_firedEH"];
|
|
_firedEH params ["_shooter","","","","","","_projectile"];
|
|
_attackProfileStateParams params["_maxCorrectableDistance", "_wireCut", "_randomVector", "_crosshairOffset", "_seekerMaxRangeSqr", "", "_wireCutSource"];
|
|
|
|
private _projectilePos = getPosASL _projectile;
|
|
|
|
if ((((getPosASL _shooter) vectorDistanceSqr _projectilePos) > _seekerMaxRangeSqr) || { _wireCut }) exitWith {
|
|
// wire snap, random direction
|
|
if (_randomVector isEqualTo [0, 0, 0]) then {
|
|
_randomVector = RANDOM_VECTOR_3D vectorMultiply 300;
|
|
_attackProfileStateParams set [1, true];
|
|
_attackProfileStateParams set [2, _randomVector];
|
|
|
|
playSound3D ["a3\sounds_f\air\sfx\SL_rope_break.wss", objNull, false, AGLtoASL (_shooter modelToWorld _wireCutSource), 150, 1, 25];
|
|
};
|
|
_projectilePos vectorAdd _randomVector
|
|
};
|
|
|
|
if (_seekerTargetPos isEqualTo [0, 0, 0]) exitWith {
|
|
// cut wire if its caught on terrain
|
|
/*if !(lineIntersectsSurfaces [getPosASL _shooter, _projectilePos, _shooter] isEqualTo []) then {
|
|
_attackProfileStateParams set [1, true];
|
|
};*/
|
|
// return position 50m infront of projectile
|
|
_projectilePos vectorAdd (_projectile vectorModelToWorld [0, 50, 0])
|
|
};
|
|
|
|
private _relativeCorrection = _projectile vectorWorldToModel (_projectilePos vectorDiff _seekerTargetPos);
|
|
_relativeCorrection = _relativeCorrection vectorDiff _crosshairOffset;
|
|
|
|
private _magnitude = vectorMagnitude [_relativeCorrection select 0, 0, _relativeCorrection select 2];
|
|
|
|
private _fovImpulse = 1 min (_magnitude / _maxCorrectableDistance); // the simulated impulse for the missile being close to the center of the crosshair
|
|
|
|
// Adjust the impulse due to near-zero values creating wobbly missiles?
|
|
private _correction = _fovImpulse;
|
|
|
|
_relativeCorrection = (vectorNormalized _relativeCorrection) vectorMultiply _correction;
|
|
|
|
_projectilePos vectorDiff (_projectile vectorModelToWorld _relativeCorrection);
|
|
|