mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
49 lines
1.4 KiB
Plaintext
49 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Handles the inventory opening.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Container <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [player, car] call ACE_VehicleLock_fnc_onOpenInventory;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_container"];
|
|
TRACE_2("params",_unit,_container);
|
|
|
|
//Only check for player:
|
|
if (_unit != ace_player) exitWith {};
|
|
|
|
if (GVAR(LockVehicleInventory) && //if setting not enabled
|
|
{(vehicle ace_player) == ace_player} && //Player dismounted
|
|
{(_container isKindOf "Car") || (_container isKindOf "Tank") || (_container isKindOf "Helicopter")} && //container is a lockable veh
|
|
{(locked _container) in [2,3]} && //Vehicle is locked
|
|
{!([ace_player, _container] call FUNC(hasKeyForVehicle))} //player doesn't have key
|
|
) then {
|
|
//Give feedback that vehicle is locked
|
|
playSound "ACE_Sound_Click";
|
|
|
|
//For compatibiltiy with ACRE, wait until the display is open, close it and then reopen the player's own inventory
|
|
//ref: http://gitlab.idi-systems.com/idi-systems/acre2-public/issues/70
|
|
[{
|
|
!isNull (findDisplay 602)
|
|
},
|
|
{
|
|
TRACE_1("car display open: closing", _this);
|
|
(findDisplay 602) closeDisplay 0;
|
|
[{
|
|
TRACE_1("Opening Player Inventory", _this);
|
|
ACE_player action ["Gear", objNull]
|
|
}, []] call CBA_fnc_execNextFrame;
|
|
},
|
|
[]] call CBA_fnc_waitUntilAndExecute;
|
|
};
|