mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
bca8b01860
* Add search to teleport players UI * Change group side icons to look better * Improve teleport UI and add stringtable entries * Add Assign Repair Vehicle module * Add Assign Repair Facility module * Add Assign Engineer module * Add Full Heal module * Add Suicide Bomber module * Make heal module work without ace_medical * Add suicide bomber module translations * Improve attribute cargo to use displayName * Improve set engineer ui * ACE_Curator for repair modules + author array * Add angle param to getModuleDestination * Prevent multiple suicide bomber modules on same target * Heal module: support BI scripted revive system * Requested changes
83 lines
2.1 KiB
Plaintext
83 lines
2.1 KiB
Plaintext
/*
|
|
* Author: SilentSpike
|
|
* Initalises the `search area` zeus module display
|
|
*
|
|
* Arguments:
|
|
* 0: dummy controls group <CONTROL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [CONTROL] call ace_zeus_fnc_ui_searchArea
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
//Generic Init:
|
|
params ["_control"];
|
|
private _display = ctrlParent _control;
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objNull);
|
|
|
|
_control ctrlRemoveAllEventHandlers "setFocus";
|
|
|
|
//Validate the module target:
|
|
private _unit = effectiveCommander (attachedTo _logic);
|
|
|
|
scopeName "Main";
|
|
private _fnc_errorAndClose = {
|
|
params ["_msg"];
|
|
_display closeDisplay 0;
|
|
deleteVehicle _logic;
|
|
[_msg] call FUNC(showMessage);
|
|
breakOut "Main";
|
|
};
|
|
|
|
switch (false) do {
|
|
case !(isNull _unit): {
|
|
[LSTRING(NothingSelected)] call _fnc_errorAndClose;
|
|
};
|
|
case (_unit isKindOf "CAManBase"): {
|
|
[LSTRING(OnlyInfantry)] call _fnc_errorAndClose;
|
|
};
|
|
case (alive _unit): {
|
|
[LSTRING(OnlyAlive)] call _fnc_errorAndClose;
|
|
};
|
|
};
|
|
|
|
private _fnc_onUnload = {
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objnull);
|
|
if (isNull _logic) exitWith {};
|
|
|
|
if (_this select 1 == 2) then {
|
|
deleteVehicle _logic;
|
|
};
|
|
};
|
|
|
|
private _fnc_onConfirm = {
|
|
params [["_ctrlButtonOK", controlNull, [controlNull]]];
|
|
|
|
private _display = ctrlparent _ctrlButtonOK;
|
|
if (isNull _display) exitWith {};
|
|
|
|
private _logic = GETMVAR(BIS_fnc_initCuratorAttributes_target,objnull);
|
|
if (isNull _logic) exitWith {};
|
|
|
|
private _unit = effectiveCommander (attachedTo _logic);
|
|
private _radius = GETVAR(_display,GVAR(radius),50);
|
|
private _position = GETVAR(_display,GVAR(position),getPos _logic);
|
|
private _marker = QGVAR(ModuleSearchArea) + str(_unit);
|
|
|
|
createMarker [_marker, _position];
|
|
_marker setMarkerAlpha 0;
|
|
_marker setMarkerShape "ELLIPSE";
|
|
_marker setMarkerSize [_radius,_radius];
|
|
|
|
[QGVAR(moduleSearchArea), [_unit,_marker], _unit] call CBA_fnc_targetEvent;
|
|
deleteVehicle _logic;
|
|
};
|
|
|
|
_display displayAddEventHandler ["unload", _fnc_onUnload];
|
|
_control ctrlAddEventHandler ["buttonClick", _fnc_onConfirm];
|