mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
57 lines
1.4 KiB
Plaintext
57 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Glowbal
|
|
* Add an entry to the specified log
|
|
*
|
|
* Arguments:
|
|
* 0: The patient <OBJECT>
|
|
* 1: The log type <STRING>
|
|
* 2: The message <STRING>
|
|
* 3: The arguments for localization <ARRAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [bob, "type", "message", [_args]] call ace_medical_treatment_fnc_addToLog
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_type", "_message", "_arguments"];
|
|
|
|
if (!local _unit) exitWith {
|
|
[QGVAR(addToMedicalLog), _this, _unit] call CBA_fnc_targetEvent;
|
|
};
|
|
|
|
date params ["", "", "", "_hour", "_minute"];
|
|
|
|
private _moment = format [["%1:%2", "%1:0%2"] select (_minute < 10), _hour, _minute];
|
|
private _logVarName = format [QEGVAR(medical,logFile_%1), _type];
|
|
private _log = _unit getVariable [_logVarName, []];
|
|
|
|
if (count _log >= 8) then {
|
|
private _newLog = [];
|
|
|
|
{
|
|
// ensure the first element will not be added
|
|
if (_forEachIndex > 0) then {
|
|
_newLog pushBack _x;
|
|
};
|
|
} forEach _log;
|
|
|
|
_log = _newLog;
|
|
};
|
|
|
|
_log pushBack [_message, _moment, _type, _arguments];
|
|
|
|
_unit setVariable [_logVarName, _log, true];
|
|
["ace_medicalLogEntryAdded", [_unit, _type, _message, _arguments]] call CBA_fnc_localEvent;
|
|
|
|
private _logs = _unit getVariable [QEGVAR(medical,allLogs), []];
|
|
|
|
if !(_logVarName in _logs) then {
|
|
_logs pushBack _logVarName;
|
|
_unit setVariable [QEGVAR(medical,allLogs), _logs, true];
|
|
};
|