mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
44050df98b
* Modernize and cleanup medical_treatment
* One line for each old public function
* Fix litterCleanupDelay name
* Improve adjustment calcs / wound blood loss / medications
fix func descriptions
Calc wound blood loss on events
reorder includes so scritpmacroMed has global effect
trivial optimization for getCardiacOutput
Fix var
Fix wounds not reopening (nil _category)
Fix surgical kit inherting canBandage conditional
debug hitpoints
Update ACE_Medical_Treatment_Actions.hpp
Use woundBleeding for IS_BLEEDING macro
rework medication vars
comments
Reset var in init / fullHeal
Update addons/medical_treatment/functions/fnc_onMedicationUsage.sqf
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* Change wound data array
Drop unique id and merge classId and category
* Splinting and treatment and gui
* Add arm fractures and aim effects
* localizations and event
* fix
* fix merge for renamed files
* Fixes and code review changes
* Move medical logs clearing to treatment
* More cleanup work
* cleanup
* Apply suggestions from code review
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* formating, rename bone images
* Fix args for setDead call in actionPlaceInBodyBag
* Apply suggestions from code review
Co-Authored-By: PabstMirror <pabstmirror@gmail.com>
* disable calls to extension
* Update fnc_onMedicationUsage.sqf
* Medical - Skip unneeded setVars on initUnit (#6949)
* Medical - Transfer state machine state on locality (#6950)
* Medical - Transfer state machine state on locality
* Fix feedback isUnconscious var
* Exclude AI
* Make UAV excludes consistant, formating
* Update fnc_treatmentFullHealLocal.sqf
* reset fractures on respawn
* Fix merge
* Add PAK time coefficient setting
* Fix medication
* Add ace_medical_replacementItems config array
* checkItems performance improvement
* Treatment - cap max animation speed (#6995)
* Treatment - cap max animation speed
and add lock to prevent AF from reseting anim
* Update fnc_getBandageTime.sqf
* Use local version of setAnimSpeedCoef
* Revert "Use local version of setAnimSpeedCoef"
This reverts commit 36c22a9047.
* Move replacementItems compiling to preInit
* Improve replacementItems compiling
* Cleanup splint functions, use macros for fractures
* Rename splintCondition to canSplint
* Add cprCreatesPulse setting
* Cleanup remaining functions
* Capitalize stringtable entry names
* getStitchTime function and fix treatment locations
* Update addons/medical_treatment/functions/fnc_getHealTime.sqf
Co-Authored-By: SilentSpike <silentspike100+Github@gmail.com>
55 lines
1.5 KiB
Plaintext
55 lines
1.5 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: SilentSpike
|
|
* Calculates the time to bandage a wound based on it's size, the patient and the medic.
|
|
*
|
|
* Arguments:
|
|
* 0: Medic <OBJECT>
|
|
* 1: Patient <OBJECT>
|
|
* 2: Body Part <STRING>
|
|
* 3: Treatment <STRING>
|
|
*
|
|
* Return Value:
|
|
* Treatment Time <NUMBER>
|
|
*
|
|
* Example:
|
|
* [player, cursorTarget, "Head", "FieldDressing"] call ace_medical_treatment_fnc_getBandageTime
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_medic", "_patient", "_bodypart", "_bandage"];
|
|
|
|
private _partIndex = ALL_BODY_PARTS find toLower _bodyPart;
|
|
if (_partIndex < 0) exitWith { 0 };
|
|
|
|
private _targetWound = [_patient, _bandage, _partIndex] call FUNC(findMostEffectiveWound);
|
|
_targetWound params ["_wound", "_woundIndex", "_effectiveness"];
|
|
TRACE_3("findMostEffectiveWound",_wound,_woundIndex,_effectiveness);
|
|
|
|
// Everything is patched up on this body part already
|
|
if (_wound isEqualTo EMPTY_WOUND) exitWith { 0 };
|
|
|
|
_wound params ["_classID", "", "_amountOf", "_bloodloss", "_damage"];
|
|
private _category = (_classID % 10);
|
|
|
|
// Base bandage time is based on wound size and remaining percentage
|
|
private _bandageTime = ([
|
|
BANDAGE_TIME_S,
|
|
BANDAGE_TIME_M,
|
|
BANDAGE_TIME_L
|
|
] select _category) * _amountOf;
|
|
|
|
// Medics are more practised at applying bandages
|
|
if ([_medic] call FUNC(isMedic)) then {
|
|
_bandageTime = _bandageTime + BANDAGE_TIME_MOD_MEDIC;
|
|
};
|
|
|
|
// Bandaging yourself requires more work
|
|
if (_medic == _patient) then {
|
|
_bandageTime = _bandageTime + BANDAGE_TIME_MOD_SELF;
|
|
};
|
|
|
|
// Nobody can bandage instantly
|
|
_bandageTime max 2
|