mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
f7f497f0ac
* add delay & logs * add remote support * isDamageAllowed check * add internal comment to setDead event * remove remote setDead EH * remove unnecessary changes * Add comments and move check below the event
42 lines
1.1 KiB
Plaintext
42 lines
1.1 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Kills a local unit.
|
|
*
|
|
* Arguments:
|
|
* 0: The unit <OBJECT>
|
|
* 1: Reason for death <STRING>
|
|
* 2: Killer <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", ["_reason", "#setDead"], ["_instigator", objNull]];
|
|
TRACE_3("setDead",_unit,_reason,_instigator);
|
|
|
|
// No heart rate or blood pressure to measure when dead
|
|
_unit setVariable [VAR_HEART_RATE, 0, true];
|
|
_unit setVariable [VAR_BLOOD_PRESS, [0, 0], true];
|
|
|
|
_unit setVariable [QEGVAR(medical,causeOfDeath), _reason, true];
|
|
|
|
// Send a local event before death
|
|
[QEGVAR(medical,death), [_unit]] call CBA_fnc_localEvent;
|
|
|
|
// (#8803) Reenable damage if disabled to prevent having live units in dead state
|
|
// Keep this after death event for compatibility with third party hooks
|
|
if !(isDamageAllowed _unit) then {
|
|
WARNING_1("setDead executed on unit with damage blocked - %1",_this);
|
|
_unit allowDamage true;
|
|
};
|
|
|
|
// Kill the unit without changing visual apperance
|
|
private _prevDamage = _unit getHitPointDamage "HitHead";
|
|
|
|
_unit setHitPointDamage ["HitHead", 1, true, _instigator];
|
|
|
|
_unit setHitPointDamage ["HitHead", _prevDamage];
|