mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
50 lines
1.6 KiB
Plaintext
50 lines
1.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Called by repair action / progress bar. Raise events to set the new hitpoint damage.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit that does the repairing <OBJECT>
|
|
* 1: Vehicle to repair <OBJECT>
|
|
* 2: Selected hitpoint <STRING>
|
|
* 3: Repair Action Classname (Not used) <STRING>
|
|
* 4: (Not used) <ARRAY>
|
|
* 5: (Not used) <ARRAY>
|
|
* 6: Required Repair Objects <ARRAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [unit, vehicle, "hitpoint", "RepairTrack", [], [], [aTrack]] call ace_repair_fnc_doRepairTrack
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_unit", "_vehicle", "_hitPoint", "", "", "", "_claimedObjects"];
|
|
TRACE_4("params",_unit,_vehicle,_hitPoint,_claimedObjects);
|
|
|
|
_claimedObjects params [["_track", objNull]];
|
|
if ((isNull _track) || {!([_unit, _track, ["isNotDragging", "isNotCarrying", "isNotOnLadder"]] call EFUNC(common,canInteractWith))}) exitWith {
|
|
ERROR_1("Bad Track", _claimedObjects);
|
|
};
|
|
|
|
// can't use a destroyed track
|
|
if ((damage _track) >= 1) exitWith {};
|
|
|
|
// get current hitpoint damage
|
|
private _hitPointDamage = _vehicle getHitPointDamage _hitPoint;
|
|
private _damageRepaired = (1 - (damage _track)) / 4; // require 4 tracks to fully replace one side
|
|
|
|
// don't die by spawning / moving the wheel
|
|
_hitPointDamage = (_hitPointDamage - _damageRepaired) min 0;
|
|
deleteVehicle _track;
|
|
|
|
// raise event to set the new hitpoint damage
|
|
[QGVAR(setWheelHitPointDamage), [_vehicle, _hitPoint, _hitPointDamage], _vehicle] call CBA_fnc_targetEvent;
|
|
|
|
// display text message if enabled
|
|
if (GVAR(DisplayTextOnRepair)) then {
|
|
[LSTRING(ReplacedTrack)] call EFUNC(common,displayTextStructured);
|
|
};
|