mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
57 lines
1.3 KiB
Plaintext
57 lines
1.3 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: jaynus
|
|
* Master single PFH abstraction for all rounds being tracked by frag/spall.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* call ace_frag_fnc_masterPFH
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
BEGIN_COUNTER(PFH);
|
|
|
|
// Fast exit if nothing to do
|
|
if (GVAR(objects) isEqualTo []) exitWith {END_COUNTER(PFH);};
|
|
|
|
private _gcIndex = [];
|
|
|
|
private _iter = 0;
|
|
private _objectCount = count GVAR(objects);
|
|
while {_objectCount > 0 && {_iter < (GVAR(maxTrackPerFrame) min _objectCount)}} do {
|
|
|
|
if (GVAR(lastIterationIndex) >= _objectCount) then {
|
|
GVAR(lastIterationIndex) = 0;
|
|
};
|
|
private _object = GVAR(objects) select GVAR(lastIterationIndex);
|
|
|
|
if (!isNil "_object") then {
|
|
private _args = GVAR(arguments) select GVAR(lastIterationIndex);
|
|
|
|
if (!(_args call FUNC(pfhRound))) then {
|
|
_gcIndex pushBack GVAR(lastIterationIndex); // Add it to the GC if it returns false
|
|
};
|
|
};
|
|
INC(_iter);
|
|
INC(GVAR(lastIterationIndex));
|
|
};
|
|
|
|
// Clean up dead object references
|
|
private _deletionCount = 0;
|
|
{
|
|
TRACE_1("GC Projectile", _x);
|
|
private _deleteIndex = _x - _deletionCount;
|
|
GVAR(objects) deleteAt _deleteIndex;
|
|
GVAR(arguments) deleteAt _deleteIndex;
|
|
|
|
INC(_deletionCount);
|
|
} forEach _gcIndex;
|
|
|
|
END_COUNTER(PFH);
|