mirror of
https://github.com/Defent/DMS_Exile.git
synced 2024-08-30 16:52:12 +00:00
70fae7bc44
* **NEW CONFIG VALUES:** DMS_SpawnFlareOnReinforcements DMS_MissionMarkerWinDot_Type DMS_MissionMarkerLoseDot_Type DMS_EnableBoxMoving DMS_BasesToImportOnServerStart DMS_AI_Classname DMS_AI_AimCoef_easy DMS_AI_AimCoef_moderate DMS_AI_AimCoef_difficult DMS_AI_AimCoef_hardcore DMS_AI_EnableStamina_easy DMS_AI_EnableStamina_moderate DMS_AI_EnableStamina_difficult DMS_AI_EnableStamina_hardcore DMS_AI_destroyStaticWeapon DMS_AI_destroyStaticWeapon_chance DMS_ai_SupportedRandomClasses DMS_random_non_assault_AI DMS_random_non_MG_AI DMS_random_non_sniper_AI * Please check out the new config values in config.sqf to see what they do :) * Fixed issue with "thieves" mission (and DMS-spawned persistent vehicles in general). Big thank you to [JamieKG from Eternal Gamer](http://eternal-gamer.com/) and Torndeco. * **New static mission: "slums"** * Credit for the base goes to [William from Refugees of the Fallen](http://refugeesofthefallen.enjin.com/) * Spawns 2 crates at 2 different locations from a list of 5 locations. * No AI vehicles, only infantry (introduces Close Quarters Combat) * Added to Altis by default. * Static bases can now be imported on server startup instead of mission spawns. Enabled by default for saltflats and slums. * Increased "DMS_MissionTimeoutResetRange" from 1000 to 1500. * Removed the Navid from config (MG AI and box weapons). * Edited panthera3_config to reduce SpawnZoneNear and TraderZoneNear blacklists. * Edited "blackhawkdown" and "donthasslethehoff" missions to use a slightly different heli wreck classname. * Increased marker circle diameter for saltflats mission to 750 meters. * Moved "DMS_Version" variable assignment to pre-init. * Moved Map Center and Map Radius assignments to post-init. * Added support for 2 new optional parameters: _onMonitorStart and _onMonitorEnd, run before and after the Mission Monitor checks the mission, but AFTER "Mission Success State" is checked. * Mines should now be deleted when a mission fails. * Script optimizations for almost all functions using new command(s) introduced in ArmA v1.54, as well as improved technique(s). * "ExileServer_system_garbageCollector_deleteObject" is now used to actually delete items by DMS_fnc_CleanUp. * AI and vehicle cleanup should now be completely handled by Exile. * Added support for mARMA logging. * **You can now disable the movement/lifting of loot crates after the mission is complete using "DMS_EnableBoxMoving".** * Added some debug code to DMS_fnc_FindSafePos and DMS_fnc_IsValidPosition (commented out by default) * New group reinforcement type "increasing_difficulty". * DMS_fnc_IsNearWater now checks for invalid parameter(s). * DMS_fnc_PlayerAwardOnAIKill now checks for roadkill values AFTER unit-defined respect/tabs. * You can now define different marker types for mission completion/failure using "DMS_MissionMarkerWinDot_Type" and "DMS_MissionMarkerLoseDot_Type" respectively. * "DMS_fnc_SetGroupBehavior" can now take a unit as parameter as well. It will also now return true if behavior was changed, false otherwise. * "DMS_fnc_SpawnAIGroup" and "DMS_fnc_SpawnAIGroup_MultiPos" now supports the definition of custom gear sets. * Improved function documentation for "DMS_fnc_SpawnAIGroup", "DMS_fnc_SpawnAIGroup_MultiPos", and "DMS_fnc_SpawnAISoldier". * "DMS_fnc_SpawnAISoldier" now supports multiple different random AI class presets. This means that you can define a certain "random" class preset, but have it select from a specially defined list that excludes classes that you don't want. * Added default values to certain "missionNameSpace getVariable"s in DMS_fnc_SpawnAISoldier to prevent script errors in the event of invalid definitions. * Slight logic tweak/fix to DMS_fnc_TargetsKilled (it shouldn't throw errors when there aren't any).
124 lines
3.6 KiB
Plaintext
124 lines
3.6 KiB
Plaintext
/*
|
|
DMS_fnc_SpawnNonPersistentVehicle
|
|
|
|
Spawns a vehicle, but it isn't saved to database by this function.
|
|
This function takes into consideration Exile config settings for enabling/disabling Night Vision and Thermal Equipment on a vehicle.
|
|
It will also apply all regular Exile EventHandlers, as well as an additional "RopeAttach" EventHandler that will enable simulation on a vehicle that is about to be lifted to prevent issues. (Only for helis)
|
|
|
|
The vehicle is LOCKED, has godmode, disabled simulation, and is not able to be slingloaded on spawn.
|
|
|
|
NOTE: This function only takes ATL, and will not necessarily spawn directly on the given pos. It will attempt to find a clear position for the given vehicle, and then spawn it at the "clear" position.
|
|
If you want the vehicle to be placed precisely at the position provided, you will have to do a setPosXXX at that position on the vehicle after spawning.
|
|
|
|
Created by Zupa
|
|
Edited by eraser1
|
|
|
|
Usage:
|
|
[
|
|
_vehicleClass, // STRING: Classname of the vehicle
|
|
_pos // ARRAY: Position to spawn it at (roughly)
|
|
] call DMS_fnc_SpawnNonPersistentVehicle;
|
|
|
|
Returns the vehicle object of the created vehicle.
|
|
|
|
EXAMPLE:
|
|
_exampleVeh = ['Exile_Chopper_Hummingbird_Green',_pos] call DMS_fnc_SpawnNonPersistentVehicle;
|
|
|
|
*/
|
|
|
|
private ["_vehicleClass","_position","_vehpos","_maxDistance","_vehObj"];
|
|
|
|
|
|
if !(params
|
|
[
|
|
["_vehicleClass","",[""]],
|
|
["_position","",[[]],[2,3]]
|
|
])
|
|
exitWith
|
|
{
|
|
diag_log format ["DMS ERROR :: Calling DMS_fnc_SpawnNonPersistentVehicle with invalid parameters: %1",_this];
|
|
objNull
|
|
};
|
|
|
|
if !(isClass (configFile >> "CfgVehicles" >> _vehicleClass)) exitWith
|
|
{
|
|
diag_log format ["DMS ERROR :: Calling DMS_fnc_SpawnNonPersistentVehicle with non-existent vehicle className: %1",_vehicleClass];
|
|
objNull
|
|
};
|
|
|
|
_vehpos = [];
|
|
_maxDistance = 5;
|
|
|
|
while{count _vehpos < 1} do
|
|
{
|
|
_vehpos = _position findEmptyPosition [0,_maxDistance,_vehicleClass];
|
|
_maxDistance = (_maxDistance + 5);
|
|
};
|
|
|
|
_vehpos set [2, 0.1];
|
|
|
|
_vehObj = createVehicle [_vehicleClass, _vehpos, [], 0, "CAN_COLLIDE"];
|
|
|
|
clearBackpackCargoGlobal _vehObj;
|
|
clearItemCargoGlobal _vehObj;
|
|
clearMagazineCargoGlobal _vehObj;
|
|
clearWeaponCargoGlobal _vehObj;
|
|
|
|
if (_vehicleClass isKindOf "I_UGV_01_F") then
|
|
{
|
|
createVehicleCrew _vehObj;
|
|
};
|
|
if (getNumber (configFile >> "CfgSettings" >> "VehicleSpawn" >> "nightVision") isEqualTo 0) then
|
|
{
|
|
_vehObj disableNVGEquipment true;
|
|
};
|
|
if (getNumber (configFile >> "CfgSettings" >> "VehicleSpawn" >> "thermalVision") isEqualTo 0) then
|
|
{
|
|
_vehObj disableTIEquipment true;
|
|
};
|
|
|
|
_vehObj setFuel (0.75+(random 0.25));
|
|
_vehObj setDir (random 360);
|
|
|
|
if ((getTerrainHeightASL _vehpos)>0) then
|
|
{
|
|
_vehObj setVectorUp (surfaceNormal _vehpos);
|
|
};
|
|
|
|
_vehObj setVariable ["ExileIsPersistent", false];
|
|
_vehObj addMPEventHandler ["MPKilled", { if !(isServer) exitWith {}; _this call ExileServer_object_vehicle_event_onMPKilled;}];
|
|
_vehObj addEventHandler ["GetIn", {_this call ExileServer_object_vehicle_event_onGetIn}];
|
|
if (_vehObj isKindOf "Helicopter") then
|
|
{
|
|
_vehObj addEventHandler ["RopeAttach",
|
|
{
|
|
private "_vehicle";
|
|
_vehicle = _this select 2;
|
|
|
|
if !(simulationEnabled _vehicle) then
|
|
{
|
|
_vehicle enableSimulationGlobal true;
|
|
};
|
|
}];
|
|
};
|
|
|
|
if (!isNil "AVS_Version") then
|
|
{
|
|
_vehObj call AVS_fnc_sanitizeVehicle;
|
|
};
|
|
|
|
_vehObj lock 2;
|
|
_vehObj allowDamage false;
|
|
_vehObj enableRopeAttach false;
|
|
_vehObj enableSimulationGlobal false;
|
|
|
|
_vehObj setVariable ["ExileIsSimulationMonitored", false];
|
|
|
|
if (DMS_DEBUG) then
|
|
{
|
|
(format ["SpawnNonPersistentVehicle :: Created %1 at %2 with calling parameters: %3",_vehObj,_vehpos,_this]) call DMS_fnc_DebugLog;
|
|
};
|
|
|
|
|
|
_vehObj
|