mirror of
https://github.com/Defent/DMS_Exile.git
synced 2024-08-30 16:52:12 +00:00
9b8e4e1573
* ** NEW CONFIG VALUES: |DMS_MaxStaticMissions| |DMS_TimeToFirstStaticMission| |DMS_TimeBetweenStaticMissions| |DMS_StaticMissionTimeOut| |DMS_StaticMissionTimeoutResetRange| |DMS_StaticMinPlayerDistance| |DMS_UsePredefinedMissionLocations| |DMS_PredefinedMissionLocations| |DMS_MinDistFromWestBorder| |DMS_MinDistFromEastBorder| |DMS_MinDistFromSouthBorder| |DMS_MinDistFromNorthBorder| |DMS_StaticMissionTypes| ** * Added new value "DMS_Version". * ** "DMS_fnc_SpawnAIStatic" is now "DMS_fnc_SpawnAIStaticMG"; donthasslethehoff, mercbase, and testmission have been updated with the new names** * DMS will now check to make sure that marker colors passed to fn_CreateMarker are valid marker colors. * You can now control how far away from each border a mission will spawn (each border is separate: west, east, south, north). All "supported" maps have config values adjusted in "map_configs". * New salt flats base by [Darth Rogue from SOA](http://soldiersofanarchy.net/). * **IMPLEMENTED STATIC MISSIONS (initial version). "saltflats" is currently the only static mission for Altis ONLY. However, it shouldn't be too difficult to export it to other maps (once positions have been adjusted). ** * Fixed a couple of outdated/inaccurate function documentation comments. * **FINALLY REMOVED THE Default Value "-1" PARAMS RPT SPAM. I FOUND IT. YESSSSS** * Fixed fn_CleanUp producing debug logs even with debug disabled. * Fixed the CleanUp list not Cleaning Up after itself (hah!). * Added diag_tickTime and DMS_Version to debug logs. * You can now define a custom function for DMS_FillCrate. It will be passed params from _lootValues select 0. ** I haven't tested this at all. Just keep that in mind ;) ** * You can now manually define mission spawning locations into an array, and that array will be used to find a location. Each location will still be checked for validity, and if no valid positions are found from the list, a random one is then generated using the normal method. ** I didn't test this part at all either :P ** * fn_FindSafePos should be even more efficient now, and even more controllable. * Quite a few new functions; most notably: fn_GroupReinforcementsManager * fn_GroupReinforcementsManager is used by static missions to provide reinforcements for AI once they fall below a certain threshold (and/or any other parameters you provide). Make sure to check out the function documentation and give any suggestions for new reinforcement types! * New function "DMS_fnc_ImportFromM3E_Static" will simply import a base from the provided file (under static). No conversion to relative position or anything. Simply spawning, positioning, and disabling simulation. * Removed the check for being outside map edges from fn_isValidPosition. * "hardcore" AI will now be even more difficult ;)
87 lines
2.0 KiB
Plaintext
87 lines
2.0 KiB
Plaintext
/*
|
|
DMS_fnc_SpawnAIStaticMG
|
|
Created by eraser1
|
|
Influenced by WAI
|
|
|
|
Usage:
|
|
[
|
|
[ // Array of static gun positions
|
|
_pos1,
|
|
_pos2,
|
|
...
|
|
_pos3
|
|
],
|
|
_group, // Group to which the AI unit(s) belongs to
|
|
_class, // Class: "random","assault","MG","sniper" or "unarmed"
|
|
_difficulty, // Difficulty: "random","static","hardcore","difficult","moderate", or "easy"
|
|
_side, // "bandit","hero", etc.
|
|
_MGClass // !OPTIONAL) String: classname of the MG. Use "random" to select a random one from DMS_static_weapons
|
|
] call DMS_fnc_SpawnAIStaticMG;
|
|
|
|
Returns an array of static gun objects.
|
|
*/
|
|
|
|
private ["_OK", "_guns", "_pos", "_MGClassInput", "_MGClass", "_gun", "_unit", "_group", "_class", "_difficulty", "_side", "_positions"];
|
|
|
|
|
|
_OK = params
|
|
[
|
|
["_positions",[],[[]]],
|
|
["_group",grpNull,[grpNull]],
|
|
["_class","random",[""]],
|
|
["_difficulty","static",[""]],
|
|
["_side","bandit",[""]]
|
|
];
|
|
|
|
if (!_OK) exitWith
|
|
{
|
|
diag_log format ["DMS ERROR :: Calling DMS_fnc_SpawnAIStaticMG with invalid parameters: %1",_this];
|
|
};
|
|
|
|
_MGClassInput = "random";
|
|
if ((count _this)>5) then
|
|
{
|
|
_MGClassInput = param [5,"random",[""]];
|
|
};
|
|
|
|
|
|
_guns = [];
|
|
|
|
{
|
|
_pos = _x;
|
|
|
|
_MGClass = _MGClassInput;
|
|
if (_MGClass == "random") then
|
|
{
|
|
_MGClass = DMS_static_weapons call BIS_fnc_selectRandom;
|
|
};
|
|
|
|
_gun = createVehicle [_MGClass, [0,0,0], [], 0, "CAN_COLLIDE"];
|
|
_gun setDir (random 360);
|
|
_gun setPosATL _pos;
|
|
_gun addEventHandler ["GetOut",{(_this select 0) setDamage 1;}];
|
|
_gun lock 2;
|
|
|
|
_group addVehicle _gun;
|
|
|
|
_guns pushBack _gun;
|
|
|
|
_unit = [_group,_pos,_class,_difficulty,_side,"Static"] call DMS_fnc_SpawnAISoldier;
|
|
|
|
_unit moveInGunner _gun;
|
|
reload _unit;
|
|
_unit setVariable ["DMS_AssignedVeh",_gun];
|
|
|
|
if (DMS_DEBUG) then
|
|
{
|
|
(format ["SpawnAIStaticMG :: Created unit %1 at %2 as static gunner in %3",_unit,_pos,_gun]) call DMS_fnc_DebugLog;
|
|
};
|
|
} forEach _positions;
|
|
|
|
|
|
if (DMS_DEBUG) then
|
|
{
|
|
(format ["SpawnAIStaticMG :: Created %1 static AI with parameters: %2",count _positions,_this]) call DMS_fnc_DebugLog;
|
|
};
|
|
|
|
_guns |