mirror of
https://github.com/Defent/DMS_Exile.git
synced 2024-08-30 16:52:12 +00:00
829943bf65
* **NEW CONFIG VALUES**: |DMS_MarkerText_ShowMissionPrefix| |DMS_MarkerText_MissionPrefix| |DMS_MarkerText_ShowAICount| |DMS_MarkerText_AIName| * New function: DMS_fnc_SpawnPersistentVehicle. It will spawn inaccessible vehicles by default and convert VALID pincode inputs to the proper format. * New mission: "Car Thieves" (thieves.sqf). It uses the new DMS_fnc_SpawnPersistentVehicle. When the mission is completed successfully, the code is displayed in the completion message. * You can now add a "prefix" to the marker text of each mission. * You can now display the number of remaining AI in the marker text (it should update about every 15 seconds). * Rearranged the missions in the config to look prettier. Don't judge. * Added the "Zamak", "Tempest", and "HEMMT" to "DMS_TransportTrucks" array. Removed "Exile_Car_Van_Black" * "dynamicTextRequest" messages will now appear at the top of the screen, so it shouldn't distract/block stuff in focus. * Fixed some spelling, improved some grammar (will require mission updates, it's really minor though).
149 lines
3.7 KiB
Plaintext
149 lines
3.7 KiB
Plaintext
/*
|
|
Sample mission (duplicate for testing purposes)
|
|
*/
|
|
|
|
// For logging purposes
|
|
_num = DMS_MissionCount;
|
|
|
|
|
|
// Set mission side (only "bandit" is supported for now)
|
|
_side = "bandit";
|
|
|
|
|
|
// find position
|
|
_pos =
|
|
[
|
|
15,DMS_WaterNearBlacklist,DMS_MaxSurfaceNormal,DMS_SpawnZoneNearBlacklist,DMS_TraderZoneNearBlacklist,DMS_MissionNearBlacklist,DMS_PlayerNearBlacklist,DMS_ThrottleBlacklists
|
|
]call DMS_fnc_findSafePos;
|
|
|
|
|
|
// Set general mission difficulty
|
|
_difficulty = "easy";
|
|
|
|
|
|
// Create AI
|
|
// TODO: Spawn AI only when players are nearby
|
|
_AICount = 3 + (round (random 1));
|
|
|
|
_group =
|
|
[
|
|
_pos, // Position of AI
|
|
_AICount, // Number of AI
|
|
"hardcore", // "random","hardcore","difficult","moderate", or "easy"
|
|
"random", // "random","assault","MG","sniper" or "unarmed" OR [_type,_launcher]
|
|
_side // "bandit","hero", etc.
|
|
] call DMS_fnc_SpawnAIGroup;
|
|
|
|
|
|
_class = (DMS_MilitaryVehicles+DMS_TransportTrucks) call BIS_fnc_SelectRandom;
|
|
|
|
//DMS_fnc_SpawnPersistentVehicle will automatically turn the pincode into a string and format it.
|
|
_pinCode = round (random 9999);
|
|
|
|
_vehicle = [_class,_pos,_pinCode] call DMS_fnc_SpawnPersistentVehicle;
|
|
|
|
|
|
|
|
// Define mission-spawned AI Units
|
|
_missionAIUnits =
|
|
[
|
|
_group // We only spawned the single group for this mission
|
|
];
|
|
|
|
// Define mission-spawned objects
|
|
_missionObjs =
|
|
[
|
|
[], // No spawned buildings
|
|
[_vehicle],
|
|
[]
|
|
];
|
|
|
|
// Define Mission Start message
|
|
_msgStart = ['#FFFF00',format ["A band of thieves are attempting to break into a %1. Eliminate them and you might get the car for yourself!",getText (configFile >> "CfgVehicles" >> _class >> "displayName")]];
|
|
|
|
// Define Mission Win message
|
|
_msgWIN = ['#0080ff',format ["Convicts have eliminated the thieves! Looks like the thieves managed to figure out that the code was %1...",_pinCode]];
|
|
|
|
// Define Mission Lose message
|
|
_msgLOSE = ['#FF0000',"The thieves cracked the code and drove off!"];
|
|
|
|
// Define mission name (for map markers, mission messages, and logging)
|
|
_missionName = "Car Thieves";
|
|
|
|
// Create Markers
|
|
_markers =
|
|
[
|
|
_pos,
|
|
_missionName,
|
|
_difficulty
|
|
] call DMS_fnc_CreateMarker;
|
|
|
|
// Record time here (for logging purposes, otherwise you could just put "diag_tickTime" into the "DMS_AddMissionToMonitor" parameters directly)
|
|
_time = diag_tickTime;
|
|
|
|
// Parse and add mission info to missions monitor
|
|
_added =
|
|
[
|
|
_pos,
|
|
[
|
|
[
|
|
"kill",
|
|
_group,
|
|
true
|
|
],
|
|
[
|
|
"playerNear",
|
|
[_pos,DMS_playerNearRadius]
|
|
]
|
|
],
|
|
[
|
|
_time,
|
|
(DMS_MissionTimeOut select 0) + random((DMS_MissionTimeOut select 1) - (DMS_MissionTimeOut select 0))
|
|
],
|
|
_missionAIUnits,
|
|
_missionObjs,
|
|
[_missionName,_msgWIN,_msgLOSE],
|
|
_markers,
|
|
_side,
|
|
_difficulty,
|
|
[]
|
|
] call DMS_fnc_AddMissionToMonitor;
|
|
|
|
// Check to see if it was added correctly, otherwise delete the stuff
|
|
if !(_added) exitWith
|
|
{
|
|
diag_log format ["DMS ERROR :: Attempt to set up mission %1 with invalid parameters for DMS_AddMissionToMonitor! Deleting mission objects and resetting DMS_MissionCount.",_missionName];
|
|
|
|
// Delete AI units and the crate. I could do it in one line but I just made a little function that should work for every mission (provided you defined everything correctly)
|
|
_cleanup = [];
|
|
{
|
|
_cleanup pushBack _x;
|
|
} forEach _missionAIUnits;
|
|
|
|
_cleanup pushBack ((_missionObjs select 0)+(_missionObjs select 1));
|
|
|
|
{
|
|
_cleanup pushBack (_x select 0);
|
|
} foreach (_missionObjs select 2);
|
|
|
|
_cleanup call DMS_fnc_CleanUp;
|
|
|
|
|
|
// Delete the markers directly
|
|
{deleteMarker _x;} forEach _markers;
|
|
|
|
|
|
// Reset the mission count
|
|
DMS_MissionCount = DMS_MissionCount - 1;
|
|
};
|
|
|
|
|
|
// Notify players
|
|
[_missionName,_msgStart] call DMS_fnc_BroadcastMissionStatus;
|
|
|
|
|
|
|
|
if (DMS_DEBUG) then
|
|
{
|
|
diag_log format ["DMS_DEBUG MISSION: (%1) :: Mission #%2 started at %3 with %4 AI units and %5 difficulty at time %6",_missionName,_num,_pos,_AICount,_difficulty,_time];
|
|
}; |