Merge pull request #2834 from acemod/addEarPlugsLoudness

Hearing - Add earplugs based on loudness and give to MGs and fix respawn issues

addons/hearing/ACE_Settings.hpp

@@ -25,4 +25,10 @@ class ACE_Settings {
         displayName = CSTRING(enabledForZeusUnits_DisplayName);
         description = CSTRING(enabledForZeusUnits_Description);
     };
+    class GVAR(autoAddEarplugsToUnits) {
+        value = 1;
+        typeName = "BOOL";
+        displayName = CSTRING(autoAddEarplugsToUnits_DisplayName);
+        description = CSTRING(autoAddEarplugsToUnits_Description);
+    };
 };

addons/hearing/CfgEventHandlers.hpp

@@ -13,7 +13,7 @@ class Extended_PostInit_EventHandlers {
 class Extended_Init_EventHandlers {
     class CAManBase {
         class GVAR(AddEarPlugs) {
-            init = QUOTE( if (local (_this select 0)) then {_this call FUNC(addEarPlugs)}; );
+            serverInit = QUOTE( _this call FUNC(addEarPlugs) );
         };
     };
 };
@@ -33,3 +33,11 @@ class Extended_Explosion_EventHandlers {
         };
     };
 };
+
+class Extended_Respawn_EventHandlers {
+    class CAManBase {
+        class ADDON {
+            respawn = QUOTE(_this call FUNC(handleRespawn));
+        };
+    };
+};

addons/hearing/CfgVehicles.hpp

@@ -137,6 +137,12 @@ class CfgVehicles {
                 typeName = "BOOL";
                 defaultValue = 1;
             };
+            class autoAddEarplugsToUnits {
+                displayName = CSTRING(autoAddEarplugsToUnits_DisplayName);
+                description = CSTRING(autoAddEarplugsToUnits_Description);
+                typeName = "BOOL";
+                defaultValue = 1;
+            };
         };
         class ModuleDescription {
             description = CSTRING(Module_Description);

addons/hearing/XEH_preInit.sqf

@@ -6,6 +6,7 @@ PREP(addEarPlugs);
 PREP(earRinging);
 PREP(explosionNear);
 PREP(firedNear);
+PREP(handleRespawn);
 PREP(hasEarPlugsIn);
 PREP(moduleHearing);
 PREP(putInEarPlugs);

addons/hearing/functions/fnc_addEarPlugs.sqf

@@ -14,29 +14,50 @@
  * Public: No
  */
 #include "script_component.hpp"
+
 params ["_unit"];
+TRACE_2("params",_unit,typeOf _unit);
 
-// Exit if hearing is disabled or soldier has earplugs already in (persistence scenarios)
-if (!GVAR(enableCombatDeafness) || {[_unit] call FUNC(hasEarPlugsIn)}) exitWith {};
+// only run this after the settings are initialized
+if !(EGVAR(common,settingsInitFinished)) exitWith {
+    EGVAR(common,runAtSettingsInitialized) pushBack [FUNC(addEarPlugs), _this];
+};
 
-private ["_launcher"];
+// Exit if hearing is disabled OR autoAdd is disabled OR soldier has earplugs already in (persistence scenarios)
+if (!GVAR(enableCombatDeafness) || {!GVAR(autoAddEarplugsToUnits)} || {[_unit] call FUNC(hasEarPlugsIn)}) exitWith {};
 
 // add earplugs if the soldier has a rocket launcher
-_launcher = secondaryWeapon _unit;
-
-if (_launcher != "") exitWith {
+if ((secondaryWeapon _unit) != "") exitWith {
+    TRACE_1("has launcher - adding",_unit);
     _unit addItem "ACE_EarPlugs";
 };
 
 // otherwise add earplugs if the soldier has a big rifle
-private ["_magazine", "_ammo"];
+if ((primaryWeapon _unit) == "") exitWith {};
 
-_magazine = primaryWeaponMagazine _unit select 0;
+(primaryWeaponMagazine _unit) params [["_magazine", ""]];
+if (_magazine == "") exitWith {};
 
-if (isNil "_magazine") exitWith {};
+private _initSpeed = getNumber (configFile >> "CfgMagazines" >> _magazine >> "initSpeed");
+private _ammo = getText (configFile >> "CfgMagazines" >> _magazine >> "ammo");
+private _count = getNumber (configFile >> "CfgMagazines" >> _magazine >> "count");
 
-_ammo = getText (configFile >> "CfgMagazines" >> _magazine >> "ammo");
+private _caliber = getNumber (configFile >> "CfgAmmo" >> _ammo >> "ACE_caliber");
+_caliber = call {
+    if (_ammo isKindOf ["ShellBase", (configFile >> "CfgAmmo")]) exitWith { 80 };
+    if (_ammo isKindOf ["RocketBase", (configFile >> "CfgAmmo")]) exitWith { 200 };
+    if (_ammo isKindOf ["MissileBase", (configFile >> "CfgAmmo")]) exitWith { 600 };
+    if (_ammo isKindOf ["SubmunitionBase", (configFile >> "CfgAmmo")]) exitWith { 80 };
+    if (_caliber <= 0) then { 6.5 } else { _caliber };
+};
+private _loudness = (_caliber ^ 1.25 / 10) * (_initspeed / 1000) / 5;
 
-if (getNumber (configFile >> "CfgAmmo" >> _ammo >> "audiblefire") > 8) then {
+//If unit has a machine gun boost effective loudness 50%
+if (_count >= 50) then {_loudness = _loudness * 1.5};
+
+TRACE_2("primaryWeapon",_unit,_loudness);
+
+if (_loudness > 0.2) then {
+    TRACE_1("loud gun - adding",_unit);
     _unit addItem "ACE_EarPlugs";
 };

addons/hearing/functions/fnc_handleRespawn.sqf

@@ -0,0 +1,35 @@
+/*
+ * Author: PabstMirror
+ * Reset earplugs on respawn, and then re-add if appropriate
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * [player] call ACE_hearing_fnc_handleRespawn;
+ *
+ * Public: No
+ */
+#include "script_component.hpp"
+
+params ["_unit"];
+TRACE_2("params",_unit,typeOf _unit);
+
+if (!local _unit) exitWith {}; //XEH should only be called on local units
+
+private _respawn = [0] call BIS_fnc_missionRespawnType;
+
+//if respawn is not Group or side:
+if (_respawn <= 3) then {
+    //Remove earplugs if they have them:
+    if (_unit getVariable ["ACE_hasEarPlugsin", false]) then {
+        TRACE_1("had EarPlugs in - removing",_unit);
+        _unit setVariable ["ACE_hasEarPlugsin", false, true];
+    };
+};
+
+//Re-add if they need them:
+[_unit] call FUNC(addEarPlugs);

addons/hearing/functions/fnc_moduleHearing.sqf

@@ -20,4 +20,5 @@ if ((_logic getVariable "DisableEarRinging") != -1) then {
 };
 
 [_logic, QGVAR(enabledForZeusUnits), "enabledForZeusUnits"] call EFUNC(common,readSettingFromModule);
+[_logic, QGVAR(autoAddEarplugsToUnits), "autoAddEarplugsToUnits"] call EFUNC(common,readSettingFromModule);
 ACE_LOGINFO("Hearing Module Initialized.");

addons/hearing/stringtable.xml

@@ -165,5 +165,11 @@
             <Portuguese>Permite que unidades remotamente controladas pelo Zeus sejam atingidas por danos auditivos.</Portuguese>
             <Spanish>Permitir a las unidades por control remoto de zeus que puedan tener daños auditivos.</Spanish>
         </Key>
+        <Key ID="STR_ACE_Hearing_autoAddEarplugsToUnits_DisplayName">
+            <English>Add earplugs to units</English>
+        </Key>
+        <Key ID="STR_ACE_Hearing_autoAddEarplugsToUnits_Description">
+            <English>Add the `ACE_EarPlugs` item to all units that have loud weapons. Can disable if using custom loadouts.</English>
+        </Key>
     </Package>
 </Project>