mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
52 lines
1.4 KiB
Plaintext
52 lines
1.4 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: BaerMitUmlaut
|
|
* Calculates the current metabolic costs for a unit.
|
|
* Calculation is done according to the Pandolf/Wojtowicz formulas.
|
|
*
|
|
* Arguments:
|
|
* 0: Unit <OBJECT>
|
|
* 1: Speed <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* Metabolic cost <NUMBER>
|
|
*
|
|
* Example:
|
|
* [player, 3.3] call ace_advanced_fatigue_fnc_getMetabolicCosts
|
|
*
|
|
* Public: No
|
|
*/
|
|
params ["_unit", "_velocity"];
|
|
|
|
private _gearMass = ((_unit getVariable [QEGVAR(movement,totalLoad), loadAbs _unit]) / 22.046) * GVAR(loadFactor);
|
|
|
|
private _terrainAngle = asin (1 - ((surfaceNormal getPosASL _unit) select 2));
|
|
private _terrainGradient = (_terrainAngle / 45 min 1) * 5 * GVAR(terrainGradientFactor);
|
|
private _duty = GVAR(animDuty);
|
|
|
|
{
|
|
if (_x isEqualType 0) then {
|
|
_duty = _duty * _x;
|
|
} else {
|
|
_duty = _duty * (_unit call _x);
|
|
};
|
|
} forEach (GVAR(dutyList) select 1);
|
|
|
|
if (GVAR(isSwimming)) then {
|
|
_terrainGradient = 0;
|
|
};
|
|
|
|
if (_velocity > 2) then {
|
|
(
|
|
2.10 * SIM_BODYMASS
|
|
+ 4 * (SIM_BODYMASS + _gearMass) * ((_gearMass / SIM_BODYMASS) ^ 2)
|
|
+ (SIM_BODYMASS + _gearMass) * (0.90 * (_velocity ^ 2) + 0.66 * _velocity * _terrainGradient)
|
|
) * 0.23 * _duty
|
|
} else {
|
|
(
|
|
1.05 * SIM_BODYMASS
|
|
+ 4 * (SIM_BODYMASS + _gearMass) * ((_gearMass / SIM_BODYMASS) ^ 2)
|
|
+ (SIM_BODYMASS + _gearMass) * (1.15 * (_velocity ^ 2) + 0.66 * _velocity * _terrainGradient)
|
|
) * 0.23 * _duty
|
|
};
|