mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
257d9536cc
* First Push Added the ability to edit cargo objects (crates/boxes only) names. Either via in-game action on the object it self or via 3den attributes. Added a single function which spawns the UI to edit the name and also edits it. This is an scripted UI, it could be changed to a config version if wanted, but as I'm not good in UI coding I left it on this simple version mainly for testing. Added 4 new stringtable entries, 2 for action and 2 for 3den attributes. * Add extra stringtable Forgot to add the UI to the stringtable. * Update fnc_renameObject.sqf fixing tabs * Show custom name only behind Added new function "getNameItem" that will get the items name. Put the custom name behind the original name between brackets "[...]". * Added "Hide Rename Action" setting Also removed an unused _itemClass from postInit. * Apply suggestions from code review Co-authored-by: jonpas <jonpas33@gmail.com> * Update AUTHORS.txt Added my name * Applied the sugesstions. * Fixed function crash * Moved to dialog. * Removed unused comment/code * Update renameMenu.hpp Fixed tabs to spaces. * Update renameMenu.hpp * move rename to common * Update addons/arsenal/ui/RscAttributes.hpp * style and use addActionToObject Co-authored-by: jonpas <jonpas33@gmail.com> Co-authored-by: PabstMirror <pabstmirror@gmail.com>
59 lines
1.7 KiB
Plaintext
59 lines
1.7 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: Glowbal
|
|
* Handle the UI data display.
|
|
*
|
|
* Arguments:
|
|
* 0: Display <DISPLAY>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [display] call ace_cargo_fnc_onMenuOpen
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
disableSerialization;
|
|
|
|
params ["_display"];
|
|
|
|
uiNamespace setVariable [QGVAR(menuDisplay), _display];
|
|
|
|
if (GVAR(interactionParadrop)) then {
|
|
(_display displayCtrl 12) ctrlSetText (localize LSTRING(paradropButton));
|
|
};
|
|
|
|
[{
|
|
disableSerialization;
|
|
private _display = uiNamespace getVariable QGVAR(menuDisplay);
|
|
if (isnil "_display") exitWith {
|
|
[_this select 1] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
|
|
if (isNull GVAR(interactionVehicle) || {(([ACE_player, GVAR(interactionVehicle)] call EFUNC(interaction,getInteractionDistance)) >= MAX_LOAD_DISTANCE) && {(vehicle ACE_player) != GVAR(interactionVehicle)}}) exitWith {
|
|
closeDialog 0;
|
|
[_this select 1] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
|
|
private _loaded = GVAR(interactionVehicle) getVariable [QGVAR(loaded), []];
|
|
private _ctrl = _display displayCtrl 100;
|
|
private _label = _display displayCtrl 2;
|
|
|
|
lbClear _ctrl;
|
|
{
|
|
private _class = if (_x isEqualType "") then {_x} else {typeOf _x};
|
|
private _displayName = [_x, true] call FUNC(getNameItem);
|
|
if (GVAR(interactionParadrop)) then {
|
|
_ctrl lbAdd format ["%1 (%2s)", _displayName, GVAR(paradropTimeCoefficent) * ([_class] call FUNC(getSizeItem))];
|
|
} else {
|
|
_ctrl lbAdd _displayName;
|
|
};
|
|
|
|
true
|
|
} count _loaded;
|
|
|
|
_label ctrlSetText format[localize LSTRING(labelSpace), [GVAR(interactionVehicle)] call DFUNC(getCargoSpaceLeft)];
|
|
}, 0, []] call CBA_fnc_addPerFrameHandler;
|