mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
13193d3e6d
* Added weight override parameter to ace_dragging_fnc_setCarryable/setDraggable - Additional optional parameter that ignores the `startCarry`/`startDrag` weight checks. - Minor `==` to `isEqualto` replacements * `count crew _target isEqualto -1` to `count crew _target isEqualto 0` * Tab Replacement - remove \t * Reverted UAV check, Params formatting, Lazy Eval * Update addons/dragging/functions/fnc_startCarry.sqf Co-Authored-By: PiZZAD0X <509thparachuteinfantry@gmail.com> * Update fnc_startDrag.sqf * Remove beta suggestion extra line additions * Update addons/dragging/functions/fnc_startDrag.sqf Co-Authored-By: PiZZAD0X <509thparachuteinfantry@gmail.com>
68 lines
2.0 KiB
Plaintext
68 lines
2.0 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: commy2
|
|
* Carry PFH
|
|
*
|
|
* Arguments:
|
|
* 0: ARGS <ARRAY>
|
|
* 0: Unit <OBJECT>
|
|
* 1: Target <OBJECT>
|
|
* 2: Timeout <NUMBER>
|
|
* 1: PFEH Id <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [[player, target, 100], 20] call ace_dragging_fnc_startCarryPFH;
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
#ifdef DEBUG_ENABLED_DRAGGING
|
|
systemChat format ["%1 startCarryPFH running", CBA_missionTime];
|
|
#endif
|
|
|
|
params ["_args", "_idPFH"];
|
|
_args params ["_unit", "_target", "_timeOut"];
|
|
|
|
// handle aborting carry
|
|
if !(_unit getVariable [QGVAR(isCarrying), false]) exitWith {
|
|
TRACE_4("carry false",_unit,_target,_timeOut,CBA_missionTime);
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
|
|
// same as dragObjectPFH, checks if object is deleted or dead OR (target moved away from carrier (weapon disasembled))
|
|
if (!alive _target || {_unit distance _target > 10}) then {
|
|
TRACE_4("dead/distance",_unit,_target,_timeOut,CBA_missionTime);
|
|
[_unit, _target] call FUNC(dropObject_carry);
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
|
|
// handle persons vs objects
|
|
if (_target isKindOf "CAManBase") then {
|
|
if (CBA_missionTime > _timeOut) exitWith {
|
|
TRACE_4("Start carry person",_unit,_target,_timeOut,CBA_missionTime);
|
|
[_unit, _target] call FUNC(carryObject);
|
|
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
} else {
|
|
if (CBA_missionTime > _timeOut) exitWith {
|
|
TRACE_4("timeout",_unit,_target,_timeOut,CBA_missionTime);
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
|
|
// drop if in timeout
|
|
private _draggedObject = _unit getVariable [QGVAR(draggedObject), objNull];
|
|
[_unit, _draggedObject] call FUNC(dropObject_carry);
|
|
};
|
|
|
|
// wait for the unit to stand up
|
|
if (stance _unit isEqualto "STAND") exitWith {
|
|
TRACE_4("Start carry object",_unit,_target,_timeOut,CBA_missionTime);
|
|
[_unit, _target] call FUNC(carryObject);
|
|
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
};
|