mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
3f1d6ffeb7
attachTo seems to have weird getpos results for a few frames. also don't show mouse wheel option for carrying man and always use 0 offset for dragging man
45 lines
1.4 KiB
Plaintext
45 lines
1.4 KiB
Plaintext
/*
|
|
* Author: commy2
|
|
* PFH for Carry Object
|
|
*
|
|
* Arguments:
|
|
* 0: ARGS <ARRAY>
|
|
* 0: Unit <OBJECT>
|
|
* 1: Target <OBJECT>
|
|
* 2: Start time <NUMBER>
|
|
* 1: PFEH Id <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [[player, target], 20] call ace_dragging_fnc_carryObjectPFH;
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
#ifdef DEBUG_ENABLED_DRAGGING
|
|
systemChat format ["%1 carryObjectPFH running", ACE_time];
|
|
#endif
|
|
|
|
params ["_args", "_idPFH"];
|
|
_args params ["_unit","_target", "_startTime"];
|
|
|
|
if !(_unit getVariable [QGVAR(isCarrying), false]) exitWith {
|
|
TRACE_2("carry false",_unit,_target);
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|
|
|
|
// drop if the crate is destroyed OR (target moved away from carrier (weapon disasembled))
|
|
if (!alive _target || {_unit distance _target > 10}) then {
|
|
TRACE_2("dead/distance",_unit,_target);
|
|
if ((_unit distance _target > 10) && {(ACE_time - _startTime) < 1}) exitWith {
|
|
//attachTo seems to have some kind of network delay and target can return an odd position durring the first few frames,
|
|
//so wait a full second to exit if out of range (this is critical as we would otherwise detach and set it's pos to weird pos)
|
|
TRACE_3("ignoring bad distance at start",_unit distance _target,_startTime,ACE_time);
|
|
};
|
|
[_unit, _target] call FUNC(dropObject_carry);
|
|
[_idPFH] call CBA_fnc_removePerFrameHandler;
|
|
};
|