mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
c4156a6888
* Initital port of ACE2 Vehicle Damage * Add fire damage and burning people * Migrate vehicle damge stuff from cookoff. Change cookoff function to enhance effect. * Minor tweaks * Add incendiary values to all applicable ammunition. Add engine fire/smoke if hit enough * Handle car damage more elegantly. * Added ability to create fire sources arbitrarily * tweaks * Add chance to detonate after cookoff * disable compile cache * Move blown-off turret config to vehicle damage. Add settings inititalized EH for initializing off settings * tabs->spaces * Various code improvements * Change to count loop for deleting effects * update addon requirements * remove vanilla config requirements * Add RHS compatability * RHS compat. Various QOL fixes/changes * Various tweaks to compats and code. * High-Explosive damage tweak * Change how penetration is calculated for parts * Fix RHS compat * Create setting for flare effect * increase burning scream sounds * swap out file name for snake_case * move incendiary values out of vehicle damage. remove medical dependency * vehicle_dammage - update all refs to snake * sqf fixes * fix fire string package caps * fix pboprefix * Default setting to on * Add variables to enable/disable ring fire to avoid goofy looking vehicles. Enhance how particles are cleaned up. Remove advanced penetration simulation. Change how fire intensity is calculated. Add setting to "disable" vehicle after cookoff * Fix bug where event handler wasn't giving the damage last. * change to snake * fix build errors * Fix UBC * Fix Order of Operations * avoid O^2 events * Make sure that no damage processing happens on dead units * Change some if statements * Keep track of player's death to stop various things * add quotes to right middle wheen * Add VD documentation * fire docs * Code quality fixes * Clarify documentation * define IDD * switch global -> server * Add newline between header and first code statement * stop the dead from suffering Its hard to tell when a unit is dead or in spectator, so check the config of the unit to determine it. * Add settings to disable cook-off effects * Delete effects if vehicle is deleted before cookoff occurs. Don't cookoff player ammo. Throw weapon better * Move fire into own PR * fix tabs and macro * Shuffle crew indices so that a random person is first on the list to be injured each time * fix effects not clearing Co-authored-by: PabstMirror <pabstmirror@gmail.com>
66 lines
2.5 KiB
Plaintext
66 lines
2.5 KiB
Plaintext
#include "script_component.hpp"
|
|
|
|
["ace_settingsInitialized", {
|
|
TRACE_1("settings init",GVAR(enabled));
|
|
if (GVAR(enabled)) then {
|
|
[QGVAR(bailOut), {
|
|
params ["_center", "_crewman", "_vehicle"];
|
|
TRACE_3("bailOut",_center,_crewman,_vehicle);
|
|
|
|
if (isPlayer _crewman) exitWith {};
|
|
if (!alive _crewman || { !( [_crewman] call EFUNC(common,isAwake))} ) exitWith {};
|
|
|
|
unassignVehicle _crewman;
|
|
_crewman leaveVehicle _vehicle;
|
|
doGetOut _crewman;
|
|
|
|
private _angle = floor (random 360);
|
|
private _dist = (30 + (random 10));
|
|
private _escape = _center getPos [_dist, _angle];
|
|
|
|
_crewman doMove _escape;
|
|
_crewman setSpeedMode "FULL";
|
|
}] call CBA_fnc_addEventHandler;
|
|
|
|
["Tank", "init", LINKFUNC(addEventHandler), true, [], true] call CBA_fnc_addClassEventHandler;
|
|
["Wheeled_APC_F", "init", LINKFUNC(addEventHandler), true, [], true] call CBA_fnc_addClassEventHandler;
|
|
|
|
if (GVAR(enableCarDamage)) then {
|
|
["Car", "init", LINKFUNC(addEventHandler), true, [], true] call CBA_fnc_addClassEventHandler;
|
|
};
|
|
|
|
// blow off turret effect
|
|
/*
|
|
Disabled temporarily due to issues with being able to repair tanks after death. Needs work
|
|
*/
|
|
/*["Tank", "killed", {
|
|
if (random 1 < 0.15) then {
|
|
(_this select 0) call FUNC(blowOffTurret);
|
|
};
|
|
}, true, [], true] call CBA_fnc_addClassEventHandler;*/
|
|
|
|
// event to add a turret to a curator if the vehicle already belonged to that curator
|
|
if (isServer) then {
|
|
[QGVAR(addTurretToEditable), {
|
|
params ["_vehicle", "_turret"];
|
|
|
|
{
|
|
if (_vehicle in curatorEditableObjects _x) then {
|
|
_x addCuratorEditableObjects [[_turret], false];
|
|
};
|
|
} forEach allCurators;
|
|
}] call CBA_fnc_addEventHandler;
|
|
};
|
|
};
|
|
|
|
// init eject from destroyed vehicle
|
|
{
|
|
[_x, "init", {
|
|
params ["_vehicle"];
|
|
if (!alive _vehicle) exitWith {};
|
|
TRACE_2("ejectIfDestroyed init",_vehicle,typeOf _vehicle);
|
|
_vehicle addEventHandler ["HandleDamage", {call FUNC(handleDamageEjectIfDestroyed)}];
|
|
}, true, [], true] call CBA_fnc_addClassEventHandler;
|
|
} forEach EJECT_IF_DESTROYED_VEHICLES;
|
|
}] call CBA_fnc_addEventHandler;
|