mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
36 lines
1.0 KiB
Plaintext
36 lines
1.0 KiB
Plaintext
#include "..\script_component.hpp"
|
|
/*
|
|
* Author: QuantX
|
|
* Gets the capacity of a fuel source's tank.
|
|
*
|
|
* Arguments:
|
|
* 0: Fuel Source <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* Fuel capacity <NUMBER> (-10 means infinte fuel, -1 means not a fuel source, >0 is a capacity in liters)
|
|
*
|
|
* Example:
|
|
* [fuelTruck] call ace_refuel_fnc_getCapacity
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [["_source", objNull, [objNull]]];
|
|
|
|
if (isNull _source) exitWith {REFUEL_DISABLED_FUEL};
|
|
|
|
private _capacity = _source getVariable QGVAR(capacity);
|
|
|
|
// Initialize fuel truck if needed
|
|
if (isNil "_capacity") then {
|
|
// Check if this object has a fuelCargo config entry
|
|
private _fuelCargo = configOf _source >> QGVAR(fuelCargo);
|
|
_capacity = if (isNumber _fuelCargo) then {getNumber _fuelCargo} else {REFUEL_DISABLED_FUEL};
|
|
|
|
// Set capacity even if this isn't a fuel source to save on config lookup time in the event this function is used in a loop
|
|
_source setVariable [QGVAR(capacity), _capacity, true];
|
|
[_source, _capacity] call FUNC(setFuel);
|
|
};
|
|
|
|
_capacity;
|