mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
c8404f496e
* Arsenal update * Fixes * Update fnc_onSelChangedLeft.sqf * Update fnc_updateUniqueItemsList.sqf * Header fixes * Fix for defines.hpp Co-authored-by: Dystopian <sddex@ya.ru> * Moved fnc_baseWeapon, filtered invalid items * Update addons/arsenal/functions/fnc_scanConfig.sqf Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Fixes and tweaks - Sorting is guaranteed to give a fixed order - Dog tags no longer throw errors when reloading the ACE arsenal mission when you had some saved in your loadout before quitting the last time you played. * Cleanup, bug fixes and additions - Added the ability to add items from "CfgMagazines" into the "Misc. items" or custom tabs. - Added "baseWeapon" class support for weapon attachments. If a weapon attachment has the config property "baseWeapon" defined, it will take that item and show that in the arsenal. - Added stronger filtering on item scopes (scope > 0 at least for every item) - Added "descending" (default, as it is now) and "ascending" sort order as a drop down menu, - Unique backpacks in containers can now be removed with either the "-" or "clear all items" button. - When sorting by a number, 2 decimal points have been added, so that when you sort by weight it returns the correct order. * More fixes and tweaks - Converted the arsenal to partially work with hashmaps instead of arrays (for configItems and virtualItems, currentItems is still an array). - Because of the above, performance of FUNC(addVirtualItems) and FUNC(removeVirtualItems) has improved immensely. - Sorting now caches results, reducing repeated sorting times drastically. - CBA disposable launchers are handled differently now: Within the arsenal, you can change weapon attachments on disposable launchers, but you can't change their magazines (primary or secondary). Item info on the right and the stats show correct information. - FUNC(addSort) now checks if the new sorting method already exists and doesn't add it if it does. - FUNC(removeSort) now exists. You can't remove the default sort type (alphabetically) to avoid problems with the arsenal. - Both FUNC(addStat) and FUNC(compileStats) actually taken priority into account now. Because of that priority on several stats needed to be tweaked. - FUNC(removeStat) ensures that there are no gaps within the stat array (so if there is an empty spot in the stats page, it's because there is a stat, but the condition for it being shown hasn't been met). * Update fnc_replaceUniqueItemsLoadout.sqf * Update fnc_onSelChangedLeft.sqf * Update fnc_scanConfig.sqf * Update docs/wiki/framework/arsenal-framework.md Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> * Minor cleanup * Baseweapon filtering * Improvements + better unique items support * Update fnc_fillRightPanel.sqf * Update fnc_onSelChangedLeft.sqf Fixed: Switching between weapons with incompatible primary magazines while a compatible secondary magazine is loaded doesn't equip the new weapon's primary magazine. * Update addons/common/functions/fnc_uniqueUnitItems.sqf Co-authored-by: PabstMirror <pabstmirror@gmail.com> * undefined variable Co-authored-by: PabstMirror <pabstmirror@gmail.com> * fix undefined loadout var * Update fnc_fillLoadoutsList.sqf --------- Co-authored-by: Dystopian <sddex@ya.ru> Co-authored-by: Grim <69561145+LinkIsGrim@users.noreply.github.com> Co-authored-by: PabstMirror <pabstmirror@gmail.com>
93 lines
2.8 KiB
Plaintext
93 lines
2.8 KiB
Plaintext
#include "script_component.hpp"
|
|
#include "..\defines.hpp"
|
|
/*
|
|
* Author: Alganthe
|
|
* Handles tab changing for the loadouts display.
|
|
*
|
|
* Arguments:
|
|
* 0: Arsenal display <DISPLAY>
|
|
* 1: Tab control <CONTROL>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
params ["_display", "_control"];
|
|
|
|
if !(ctrlEnabled _control || {GVAR(currentLoadoutsTab) == ctrlIDC _control}) exitWith {};
|
|
|
|
private _centerBoxTitleCtrl = _display displayCtrl IDC_centerTitle;
|
|
private _shareButtonCtrl = _display displayCtrl IDC_buttonShare;
|
|
private _saveButtonCtrl = _display displayCtrl IDC_buttonSave;
|
|
private _loadButtonCtrl = _display displayCtrl IDC_buttonLoad;
|
|
private _deleteButtonCtrl = _display displayCtrl IDC_buttonDelete;
|
|
private _renameButtonCtrl = _display displayCtrl IDC_buttonRename;
|
|
|
|
// Update UI visual elements
|
|
if (GVAR(currentLoadoutsTab) != -1) then {
|
|
private _previousCtrlBackground = _display displayCtrl (GVAR(currentLoadoutsTab) - 1);
|
|
_previousCtrlBackground ctrlSetBackgroundColor [0, 0, 0, 0.8];
|
|
_previousCtrlBackground ctrlCommit 0;
|
|
|
|
private _previousCtrl = _display displayCtrl GVAR(currentLoadoutsTab);
|
|
_previousCtrl ctrlSetTextColor [1, 1, 1, 1];
|
|
_previousCtrl ctrlCommit 0;
|
|
};
|
|
|
|
private _ctrlBackground = _display displayCtrl ((ctrlIDC _control) - 1);
|
|
_ctrlBackground ctrlSetBackgroundColor [1, 1, 1, 0.8];
|
|
_ctrlBackground ctrlCommit 0;
|
|
|
|
_control ctrlSetTextColor [0, 0, 0, 1];
|
|
_control ctrlCommit 0;
|
|
|
|
switch (ctrlIDC _control) do {
|
|
// Local loadouts
|
|
case IDC_buttonMyLoadouts: {
|
|
_centerBoxTitleCtrl ctrlSetText LLSTRING(tabMyLoadoutsText);
|
|
|
|
if (is3DEN) then {
|
|
_saveButtonCtrl ctrlSetTooltip format ["%1\n%2", LLSTRING(buttonSaveTooltip), LLSTRING(buttonSaveTooltip_shiftClick)];
|
|
};
|
|
|
|
_saveButtonCtrl ctrlEnable true;
|
|
_saveButtonCtrl ctrlCommit 0;
|
|
};
|
|
// Default loadouts
|
|
case IDC_buttonDefaultLoadouts: {
|
|
_centerBoxTitleCtrl ctrlSetText LLSTRING(tabDefaultLoadoutsText);
|
|
|
|
if (is3DEN) then {
|
|
_saveButtonCtrl ctrlSetTooltip LLSTRING(buttonSaveTooltip);
|
|
};
|
|
|
|
_saveButtonCtrl ctrlEnable is3DEN;
|
|
_saveButtonCtrl ctrlCommit 0;
|
|
};
|
|
// Shared loadouts
|
|
case IDC_buttonSharedLoadouts: {
|
|
_centerBoxTitleCtrl ctrlSetText LLSTRING(tabSharedLoadoutsText);
|
|
|
|
if (is3DEN) then {
|
|
_saveButtonCtrl ctrlSetTooltip LLSTRING(buttonSaveTooltip);
|
|
};
|
|
|
|
_saveButtonCtrl ctrlEnable false;
|
|
_saveButtonCtrl ctrlCommit 0;
|
|
};
|
|
};
|
|
|
|
{
|
|
_x ctrlEnable false;
|
|
_x ctrlCommit 0;
|
|
} forEach [_shareButtonCtrl, _loadButtonCtrl, _deleteButtonCtrl, _renameButtonCtrl];
|
|
|
|
// Save new tab as current tab
|
|
GVAR(currentLoadoutsTab) = ctrlIDC _control;
|
|
|
|
[QGVAR(loadoutsTabChanged), [_display, _control]] call CBA_fnc_localEvent;
|
|
|
|
[_display, _control] call FUNC(fillLoadoutsList);
|