mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
cc414de8d1
* Initial commit advanced fatigue * Added animation changes * Fixes, rewrites * Broadcast 3den attribute and fix UBC * Further animation tweaks * Added Eden attribute and CBA settings * Switch to CBA events * Add beautified component name * Rewrites, fixes, tweaks * Move setVars to GVARs * Add setting to disable * Switch to status effect handler for sprint and jog blocking * Add component name * Failsafe for early unit player EH * Removed raised weapon penalty for pistols * Added respawn compatibility * Tweaked side jog animation speed * Added support for virtual load * Added stamina bar * Remove debug flags * Added custom duty factor functions and values * Added structural comments * Disabled CBA settings, added ACE settings * Fixed config * Added readme * Remove leftover debug diag_logs * Improved stringtable
58 lines
2.3 KiB
Plaintext
58 lines
2.3 KiB
Plaintext
/*
|
|
* Author: BaerMitUmlaut
|
|
* Handles switching units (once on init and afterwards via Zeus).
|
|
*
|
|
* Arguments:
|
|
* 0: New Unit <OBJECT>
|
|
* 1: Old Unit <OBJECT>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*/
|
|
#include "script_component.hpp"
|
|
params ["_newUnit", "_oldUnit"];
|
|
|
|
if !(isNull _oldUnit) then {
|
|
_oldUnit enableStamina true;
|
|
_oldUnit removeEventHandler ["AnimChanged", _oldUnit getVariable [QGVAR(animHandler), -1]];
|
|
|
|
_oldUnit setVariable [QGVAR(ae1Reserve), GVAR(ae1Reserve)];
|
|
_oldUnit setVariable [QGVAR(ae2Reserve), GVAR(ae2Reserve)];
|
|
_oldUnit setVariable [QGVAR(anReserve), GVAR(anReserve)];
|
|
_oldUnit setVariable [QGVAR(anFatigue), GVAR(anFatigue)];
|
|
_oldUnit setVariable [QGVAR(muscleDamage), GVAR(muscleDamage)];
|
|
};
|
|
|
|
_newUnit enableStamina false;
|
|
|
|
// Don't add a new EH if the unit respawned
|
|
if (_newUnit getVariable [QGVAR(animHandler), -1] == -1) then {
|
|
private _animHandler = _newUnit addEventHandler ["AnimChanged", {
|
|
GVAR(animDuty) = _this call FUNC(getAnimDuty);
|
|
}];
|
|
_newUnit setVariable [QGVAR(animHandler), _animHandler];
|
|
};
|
|
|
|
GVAR(ae1Reserve) = _newUnit getVariable [QGVAR(ae1Reserve), AE1_MAXRESERVE];
|
|
GVAR(ae2Reserve) = _newUnit getVariable [QGVAR(ae2Reserve), AE2_MAXRESERVE];
|
|
GVAR(anReserve) = _newUnit getVariable [QGVAR(anReserve), AN_MAXRESERVE];
|
|
GVAR(anFatigue) = _newUnit getVariable [QGVAR(anFatigue), 0];
|
|
GVAR(muscleDamage) = _newUnit getVariable [QGVAR(muscleDamage), 0];
|
|
|
|
// Clean variables for respawning units
|
|
{
|
|
_newUnit setVariable [_x, nil];
|
|
} forEach [QGVAR(ae1Reserve), QGVAR(ae2Reserve), QGVAR(anReserve), QGVAR(anFatigue), QGVAR(muscleDamage)];
|
|
|
|
GVAR(VO2Max) = 35 + 20 * (_newUnit getVariable [QGVAR(performanceFactor), GVAR(performanceFactor)]);
|
|
GVAR(VO2MaxPower) = GVAR(VO2Max) * SIM_BODYMASS * 0.23 * JOULES_PER_ML_O2 / 60;
|
|
GVAR(peakPower) = VO2MAX_STRENGTH * GVAR(VO2MaxPower);
|
|
|
|
GVAR(ae1PathwayPower) = GVAR(peakPower) / (13.3 + 16.7 + 113.3) * 13.3 * ANTPERCENT ^ 1.28 * 1.362;
|
|
GVAR(ae2PathwayPower) = GVAR(peakPower) / (13.3 + 16.7 + 113.3) * 16.7 * ANTPERCENT ^ 1.28 * 1.362;
|
|
GVAR(anPathwayPower) = GVAR(peakPower) - _ae1PathwayPower - _ae2PathwayPower;
|
|
|
|
GVAR(ppeBlackoutLast) = 100;
|
|
GVAR(lastBreath) = 0;
|
|
GVAR(animDuty) = [_newUnit, animationState _newUnit] call FUNC(getAnimDuty);
|