mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
e2ac18a05d
* advanced_ballistics * advanced_fatigue * advanced_throwing * ai * aircraft * arsenal * atragmx * attach * backpacks * ballistics * captives * cargo * chemlights * common * concertina_wire * cookoff * dagr * disarming * disposable * dogtags * dragging * explosives * fastroping * fcs * finger * frag * gestures * gforces * goggles * grenades * gunbag * hearing * hitreactions * huntir * interact_menu * interaction * inventory * kestrel4500 * laser * laserpointer * logistics_uavbattery * logistics_wirecutter * magazinerepack * map * map_gestures * maptools * markers * medical * medical_ai * medical_blood * medical_menu * microdagr * minedetector * missileguidance * missionmodules * mk6mortar * modules * movement * nametags * nightvision * nlaw * optics * optionsmenu * overheating * overpressure * parachute * pylons * quickmount * rangecard * rearm * recoil * refuel * reload * reloadlaunchers * repair * respawn * safemode * sandbag * scopes * slideshow * spectator * spottingscope * switchunits * tacticalladder * tagging * trenches * tripod * ui * vector * vehiclelock * vehicles * viewdistance * weaponselect * weather * winddeflection * yardage450 * zeus * arsenal defines.hpp * optionals * DEBUG_MODE_FULL 1 * DEBUG_MODE_FULL 2 * Manual fixes * Add SQF Validator check for #include after block comment * explosives fnc_openTimerUI * fix uniqueItems
47 lines
1.6 KiB
Plaintext
47 lines
1.6 KiB
Plaintext
#include "script_component.hpp"
|
|
/*
|
|
* Author: PabstMirror
|
|
* Opens the rangetable and fills the charge listbox.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [] call ace_mk6mortar_fnc_rangeTableOpen
|
|
*
|
|
* Public: No
|
|
*/
|
|
|
|
#define LIST_CHARGE ((uiNamespace getVariable "ACE_82mm_RangeTable_Dialog") displayCtrl 1501)
|
|
|
|
private _weaponName = "mortar_82mm"; //todo: work on other weapons
|
|
|
|
createDialog "ACE_82mm_RangeTable_Dialog";
|
|
if (isNull (uiNamespace getVariable ["ACE_82mm_RangeTable_Dialog", displayNull])) exitWith {ERROR("Dialog failed to open");};
|
|
|
|
//Get Magazine Types
|
|
private _magazines = getArray (configFile >> "CfgWeapons" >> _weaponName >> "magazines");
|
|
|
|
//For now just get settings from first mag, all rounds have same flight characteristics:
|
|
if ((count _magazines) < 1) exitWith {ERROR("No Magazines for weapon");};
|
|
private _initSpeed = getNumber (configFile >> "CfgMagazines" >> (_magazines select 0) >> "initSpeed");
|
|
|
|
//Get Charge Modes
|
|
private _fireModes = getArray (configFile >> "CfgWeapons" >> _weaponName >> "modes");
|
|
|
|
private _muzzleVelocities = [];
|
|
{
|
|
private _showToPlayer = getNumber (configFile >> "CfgWeapons" >> _weaponName >> _x >> "showToPlayer");
|
|
if (_showToPlayer == 1) then {
|
|
private _artilleryCharge = getNumber (configFile >> "CfgWeapons" >> _weaponName >> _x >> "artilleryCharge");
|
|
LIST_CHARGE lbAdd format ["%1: %2", (localize LSTRING(rangetable_charge)), (count _muzzleVelocities)];
|
|
LIST_CHARGE lbSetData [(count _muzzleVelocities), str (_artilleryCharge * _initSpeed)];
|
|
_muzzleVelocities pushBack _artilleryCharge;
|
|
};
|
|
} forEach _fireModes;
|
|
|
|
LIST_CHARGE lbSetCurSel 0;
|