mirror of
https://github.com/acemod/ACE3.git
synced 2024-08-30 18:23:18 +00:00
4466f9e785
* Move litter to `treatment` * Move eden object attributes to `treatment` * Move treatment items to `treatment` * Move bodybag handling to `treatment` * Move state conditions to `statemachine` * Move radio addon handling to `feedback` * Move medical macros to `engine` * Move medical extension to `damage` * Fix texture and material paths after move * Remove duplicate medical menu config * Remove old faction class * Remove a bunch of old code
39 lines
1.1 KiB
Plaintext
39 lines
1.1 KiB
Plaintext
/*
|
|
* Author: Ruthberg
|
|
* Handle incapacitation due to damage and pain
|
|
*
|
|
* Arguments:
|
|
* 0: The Unit <OBJECT>
|
|
*
|
|
* ReturnValue:
|
|
* nothing
|
|
*
|
|
* Public: No
|
|
*/
|
|
#include "script_component.hpp"
|
|
|
|
params ["_unit"];
|
|
|
|
private _painLevel = GET_PAIN_PERCEIVED(_unit);
|
|
private _bodyPartDamage = _unit getVariable [QEGVAR(medical,bodyPartDamage), [0,0,0,0,0,0]];
|
|
|
|
_bodyPartDamage params ["_headDamage", "_bodyDamage", "_leftArmDamage", "_rightArmDamage", "_leftLegDamage", "_rightLegDamage"];
|
|
|
|
// Exclude non penetrating body damage
|
|
{
|
|
_x params ["", "", "_bodyPartN", "_amountOf", "", "_damage"];
|
|
if (_bodyPartN == 1 && {_damage < PENETRATION_THRESHOLD}) then {
|
|
_bodyDamage = _bodyDamage - (_amountOf * _damage);
|
|
};
|
|
} forEach (_unit getVariable [QEGVAR(medical,openWounds), []]);
|
|
|
|
private _damageThreshold = if (isPlayer _unit) then {
|
|
EGVAR(medical,playerDamageThreshold)
|
|
} else {
|
|
EGVAR(medical,AIDamageThreshold)
|
|
};
|
|
|
|
if ((_headDamage > _damageThreshold / 2) || {_bodyDamage > _damageThreshold} || {(_painLevel >= PAIN_UNCONSCIOUS) && {random 1 < 0.1}}) then {
|
|
[QEGVAR(medical,CriticalInjury), _unit] call CBA_fnc_localEvent;
|
|
};
|