mirror of
https://github.com/EpochModTeam/Epoch.git
synced 2024-08-30 18:22:13 +00:00
87c23b106f
* first build for 0.3.8 * 0.3.8.0190 * 0.3.8.0202 * 0.3.8.0213 * 0.3.7.0214 * 0.3.8.0222 * 0.3.8.0246 * 0.3.8.0247 fixed typo * 0.3.8.0249 more fixes for server compiler * 0.3.8.0256 * add build number and simple batch file for packing * match build number with internal * add build numbers to server pbo's and mission files also reworked build script for more options * 0.3.8.0261 * 0.3.8.0261 * 0.3.8.0283 * 0.3.8.0284 * changelog * 0.3.8.0307 * 0.3.8.0311 * remove old BEC plugin * update redis-server.exe to latest build and full config * 0.3.8.0314 * 0.3.8.0315 * inverse logic This should correctly prevent spawning these units nearby jammer or protection zones * use pushbackUnique here * optimized loot function by using selectRandom instead of slower sqf logic * 0.3.8.0316 * make use of new getDir functionality instead of BIS fnc * add lower disconnect value to server.cfg * use new getpos functionality * 0.3.8.0317 * 0.3.8.0319 * 0.3.8.0327 * 0.3.8.0338 changelog update tba * changelog * 0.3.8.0341 * BE update * 0.3.8.0353 * changelog * removed duplicates * 0.3.8.0355 fixed error in getIDC * 0.3.8.0356 revert to BIS_fnc_param as params threw errors * 0.3.8.0357 fixes for #496 #497 * 0.3.8.0359 fixed #497 fixed #496 * 0.3.8.0365 * 0.3.8.0371 * 0.3.8.0373 * 0.3.8.0379 * 0.3.8.0381 * 0.3.8.0386 * 0.3.8.0393 * 0.3.8.0395 * 0.3.8.0396 * 0.3.8.0397 * 0.3.8.0406 * 0.3.8.0409 * 0.3.8.0410 loot balance suppress error in spawnloot make near object check based on building size * 0.3.8.0412 * 0.3.8.0414 removed classes with scope 0 test remove loot trash on gear for #498 fixed #501 * 0.3.8.0415 * same
62 lines
2.0 KiB
Plaintext
62 lines
2.0 KiB
Plaintext
/*
|
|
Author: Aaron Clark - EpochMod.com
|
|
|
|
Contributors:
|
|
|
|
Description:
|
|
Creates animals with custom Epoch fsm AI "brain"
|
|
|
|
Licence:
|
|
Arma Public License Share Alike (APL-SA) - https://www.bistudio.com/community/licenses/arma-public-license-share-alike
|
|
|
|
Github:
|
|
https://github.com/EpochModTeam/Epoch/tree/master/Sources/epoch_code/compile/environment/EPOCH_client_loadAnimalBrain.sqf
|
|
|
|
Example:
|
|
call EPOCH_client_loadAnimalBrain;
|
|
|
|
Parameter(s):
|
|
None
|
|
|
|
Returns:
|
|
NOTHING
|
|
*/
|
|
private ["_randomAIClass","_animalPos","_tryAnimalPos","_id","_animal","_animalAiTables","_playerPos"];
|
|
|
|
// TODO: move static arrays to config
|
|
if (count(player nearEntities["Animal_Base_F", 200]) >= 1) exitWith{};
|
|
|
|
_animalAiTables = ["Sheep_random_EPOCH", "Sheep_random_EPOCH", "Goat_random_EPOCH", "Goat_random_EPOCH", "Goat_random_EPOCH", ["Cock_random_EPOCH", "Hen_random_EPOCH"], ["Cock_random_EPOCH", "Hen_random_EPOCH"], "Rabbit_EPOCH", "Rabbit_EPOCH", "Rabbit_EPOCH", "Snake_random_EPOCH", "Snake2_random_EPOCH", ["Fin_random_EPOCH", "Alsatian_Random_EPOCH"]];
|
|
_randomAIClass = selectRandom _animalAiTables;
|
|
_animalPos = nil;
|
|
_playerPos = position player;
|
|
|
|
if (_randomAIClass isEqualType []) then {
|
|
_randomAIClass = selectRandom _randomAIClass;
|
|
};
|
|
|
|
for "_i" from 1 to 3 step 1 do {
|
|
_tryAnimalPos = player getPos [floor(random 350) + 50, floor(random 360)];
|
|
if!(surfaceIsWater _tryAnimalPos) exitWith {
|
|
_animalPos = _tryAnimalPos;
|
|
};
|
|
};
|
|
|
|
if!(isNil "_animalPos") then {
|
|
_animal = createAgent[_randomAIClass, _animalPos, [], 5, "NONE"];
|
|
_animal setVariable["BIS_fnc_animalBehaviour_disable", true];
|
|
|
|
// send to server
|
|
[_animal] remoteExec ["EPOCH_localCleanup",2];
|
|
|
|
{
|
|
_animal disableAI _x;
|
|
}forEach ["TARGET","AUTOTARGET","FSM"];
|
|
|
|
if (_randomAIClass in ["Fin_random_EPOCH", "Alsatian_Random_EPOCH"]) then {
|
|
_id = [_animal] execFSM "\x\addons\a3_epoch_code\System\Dog_Brain.fsm";
|
|
}else{
|
|
_id = [_animal, _randomAIClass in ["Snake_random_EPOCH","Snake2_random_EPOCH"]] execFSM "\x\addons\a3_epoch_code\System\Animal_brain.fsm";
|
|
};
|
|
};
|